(21-07-2017, Saat: 15:54)Fesih ARSLAN Adlı Kullanıcıdan Alıntı: [ -> ] (21-07-2017, Saat: 15:38)Tuğrul HELVACI Adlı Kullanıcıdan Alıntı: [ -> ]Gördüğüm kadarı ile PERSONEL tablosundaki KULLANICI_ADI alanı unique index. Aksi durumda, aynı kullanıcı adı ve şifresine sahip birden fazla kayıt olur ise bu durum sıkıntı yaratabilir. Aynı zamanda, tablo üzerinde bir güncelleme işlemi başlattığınız için, bir transaction başlatmanız ve BEGIN TRY/BEGIN CATCH ile oluşabilecek hataları da kontrol etmek isteyebilirsiniz. Örneğin:
CREATE PROCEDURE [dbo].[Kullanici_Dogrula]
@KulaniciAdi NVARCHAR(20),
@Sifre NVARCHAR(20)
AS
BEGIN
SET NOCOUNT ON;
DECLARE
@PersonelID INT
-- Kullanıcı Adı'nın unique index olma durumu söz konusu olmalı.
SELECT @PersonelID = ISNULL(
(
SELECT TOP 1
ID
FROM dbo.PERSONEL
WHERE
KULLANICI_ADI = @KulaniciAdi AND
SIFRE = @Sifre
), -1
)
IF @PersonelID <> -1
BEGIN
BEGIN TRANSACTION;
BEGIN TRY
UPDATE dbo.PERSONEL
SET SON_GIRIS = GETDATE()
WHERE
ID = @PersonelID
END TRY
BEGIN CATCH
IF @@TRANCOUNT > 0 ROLLBACK TRANSACTION;
RAISERROR('Belirtilen kullanıcı (%s) sistemde kayıtlı değil.!', 16, 1, @KullaniciAdi)
RETURN -1
END CATCH
IF @@TRANCOUNT > 0 COMMIT TRANSACTION;
END
SELECT @PersonelID AS ID
Tavsiyeleriniz için teşekkür ederim hocam.
KULLANICI_ADI ve SIFRE alanlarının aynı olma ihtimali biraz düşük, fakat yazılımcı olarak; milyonda bir ihtimal bile olsa bu durum göz ardı edilmemelidir. Bu noktada, her iki alanın Unique olmaması (aynı kullanıcı adı ve şifreye sahip birden fazla kullanıcı) durumunda, metod nasıl olmalı?
Yada mevcut sistemlerde (NVİ, e-Devlet vb.) olduğu gibi unique olması açısından TC Kimlik Numarası mı kullanılmalı?
SON_GIRIS alanının farklı bir tablo üzerinde bir PersonelId ile yer alması durumunda, yine de transaction başlatmak gerekiyor mu?
Rica ederim üstad. Benim tablo tasarımı sırasında düsturum, her bir tablo içinde ID isminde otomatik artan değer alan bir primary key'e sahip alan ve tablo içinde bir unique index. Tablonuzda unique index olmaya müsait bir alan var ise muhakkak bir unique index verin. Ancak yok ise, örneğinizden yola çıkarak aynı kullanıcı adı ve şifresine sahip birden fazla kayıt gelebilir. Bu durumda hangi kullanıcının son giriş tarihini güncelleyeceğinizi bilemezsiniz. Hata durumu oluşmasın (subquery returned more than one value) diye TOP 1 kıstası koyduk.
Ama mantıksak olarak doğru bir durum değil tabii. Personel tablonuzun durumuna bakarak, KullanıcıAdı alanının unique olması gerektiğini düşünüyorum. Çeşitli nedenlerden ötürü unique olamıyor ise, tablonuzda unique olacak bir alan üzerinden sorgulama yapmanızı öneriyorum.
Transaction ve Begin Try/Begin Catch bloklarına gelince. Bu bir tercih meselesi esasen. Ben kullanıcıların karşısına çıkacak hata mesajlarının (SQL Server'ın diline bağlı olarak) ancak programcıların anlayabileceği hata mesajları olmasını sevmiyorum. Kullanıcının anlayabileceği hata mesajları ile karşılaşması gerektiğine inanıyorum. Bu nedenle benzer bir yapı kullanıyorum. Bu tarz bir yapı aynı zamanda, oluşan hata mesajlarını da log'layabilmeme yardımcı oluyor.
Tabii transaction'un opsiyonel olma durumundan zaruri olma durumuna geçtiği bazı özel şartlarda olabilir. Örneğin:
UPDATE Tablonuz
SET
Alanınız = ISNULL(@NullableParameteniz, Alanınız)
WHERE
UniqueIndexiniz = UniqueIndexDegeriniz
UPDATE Tablonuz2
SET
Alanınız2 = ISNULL(@NullableParameteniz2, Alanınız2)
WHERE
UniqueIndexiniz2 = UniqueIndexDegeriniz2
DELETE Tablonuz3
WHERE
UniqueIndexiniz3 = UniqueIndexDegeriniz3
gibi birden fazla tablonun etkilendiği durum söz konusu ise kesinlikle bir transaction başlatmanızı öneririm. Aksi taktirde veri tabanı bütünlüğünü bozabilirsiniz. Birinci tablonuzu hatası bir şekilde güncelleyebilir ama ikinci tablonuzun güncellenmesi sırasında bir hata ile karşılaşabilirsiniz. Bir transaction başlatmadığınız için birinci tablonuz güncel değeri ile kalmış olur. Ya da bir ve ikinci tablolarınızı hatası bir şekilde güncelleyebilir ama üçüncü tablonuzdan kayıt siler iken bir hata ile karşılaşabilirsiniz. Bu durumda, birinci ve ikinci tablonuzda olmaması gereken güncellemeler kalıcı hale gelmiş olur. Yukarıdaki korumasız sorgu aşağıdaki gibi kodlanır ise veri bütünlüğünü de sağlamış olursunuz.(Ya hep/ya hiç, ya herro/ya merro)
BEGIN TRANSACTION;
BEGIN TRY
UPDATE Tablonuz
SET
Alanınız = ISNULL(@NullableParameteniz, Alanınız)
WHERE
UniqueIndexiniz = UniqueIndexDegeriniz
UPDATE Tablonuz2
SET
Alanınız2 = ISNULL(@NullableParameteniz2, Alanınız2)
WHERE
UniqueIndexiniz2 = UniqueIndexDegeriniz2
DELETE Tablonuz3
WHERE
UniqueIndexiniz3 = UniqueIndexDegeriniz3
END TRY
BEGIN CATCH
IF @@TRANCOUNT > 0 ROLLBACK TRANSACTION;
RAISERRROR('Hata mesajınız', 16, 1)
RETURN -1
END CATCH
IF @@TRANCOUNT > 0 COMMIT TRANSACTION;
Bu sayede, işlemleriniz ya tam manası ile olumlu olur; ya da hiç bir şey olmamış gibi olur. Ayrıca Begin Catch/End Catch blogları arasında oluşan hataları loglamak ister iseniz, aşağıdaki gibi bir procedure kullanabilirsiniz:
CREATE PROCEDURE [dbo].[sysSaveErrors]
@Message NVARCHAR(500) = NULL
AS
DECLARE
@ErrorNumber INT
IF ERROR_NUMBER() IS NULL RETURN;
-- Triggerların içinde kaç tane begin transaction olursa olsun; bir adet rollback transaction tüm transactionları rollback eder.
-- Örneğin 3 adet Begin Transaction'ın ardından global @@TRANCOUNT değeri 3 iken, bir adet rollback çağrımı @@TRANCOUNT değerini
-- otomatikman sıfıra çeker. Bu değerin sıfır olması durumunda SQL Server 3609 hata mesajını verir.!
IF (SELECT ERROR_NUMBER()) IN (3609, 3616) RETURN;
IF XACT_STATE() = -1 -- Açık kalmış bir transaction var ve açık bir transaction varken
BEGIN -- SQL Server Kayıt girişi/güncelleme gibi işlemlere müsaade etmez.
RAISERROR('Açık kalmış bir transaction var. Lütfen önce ROLLBACK yapın.', 16,1);
RETURN;
END
SET NOCOUNT ON;
SET @ErrorNumber = ERROR_NUMBER()
BEGIN TRY
INSERT INTO Errors(
ErrorNumber,
ErrorLine,
ErrorMessage,
ErrorProcedure,
ErrorSeverity,
ErrorState
)
SELECT
ERROR_NUMBER(),
ERROR_LINE(),
CASE
WHEN ISNULL(@Message, '') = '' THEN ''
ELSE @Message + CHAR(13) + CHAR(10)
END + ERROR_MESSAGE(),
ERROR_PROCEDURE(),
ERROR_SEVERITY(),
ERROR_STATE();
END TRY
BEGIN CATCH
END CATCH
SET NOCOUNT OFF;
DECLARE
@ErrorMessage NVARCHAR(4000)
SET @ErrorMessage =
CASE
WHEN ISNULL(@Message, '') = '' THEN ''
ELSE @Message + CHAR(13) + CHAR(10)
END + ERROR_MESSAGE()
IF EXISTS(
SELECT *
FROM master.sys.messages
WHERE
message_id = @ErrorNumber AND
@ErrorNumber >= 50000
)
RAISERROR(@ErrorNumber , 16,1)
ELSE
RAISERROR(@ErrorMessage, 16,1);
Not: Maalesef kod editörlerimiz tab tuşlarını göz ardı ediyor. Dolayısı ile örnek olması bağlamında burada paylaştığımız kodlar biraz dağınık görünüyor. Biraz düzenlemeye çalıştım ama, ancak bu kadar olabildi. :-)