Delphi Can

Orjinalini görmek için tıklayınız: Delphi Webbroker ile IMG etiketi
Şu anda (Arşiv) modunu görüntülemektesiniz. Orjinal Sürümü Görüntüle internal link
Merhaba arkadaşlar,
Uzun bir aradan sonra Delphi Webbroker ile bir web sayfası yapayım dedim. Daha önce Normal WebBroker uygulamaları yapmış ve IIS 6.0 ile çalıştırmıştım.  Ancak şimdi "Stand-Alone GUI Applicatioan" tarzında yapmak istiyorum. Bu durumda <IMG> gibi etiketlerde örneğin SRC="r1.jpg" şeklinde yazdığımda burdaki r1.jpg exe dosyası ile aynı klasörde olmasına rağmen web sayfasında gösterilemiyor. Bu gibi kaynak dosyaları nerede saklamalı ve nasıl kullanmalıyım?
Teşekkür ederim.
Bilgisayarınıza bir IIS Web sunucusu kurmadıysanız resimlere webbrowser üzerinden ulaşılamaması doğal. Bir WWWRoot kurmak gerekir ve resmi oraya koymak gerekir. Şart mı? Değil, izah edeyim. 

Diğer yandan bunu siz de yapabilirsiniz. StandAlone teriminin altını da doldurmuş olursunuz. Nasıl mı? 

Bu delphican linkinde bir örnek hazırlamıştım. Bir resmi action tanımlayıp nasıl stream edildiği kısmı inceleyebilirsiniz.

O örnek bir stand alone webbroker örneğidir. Küçük ölçekli projelerde, browser ile projenize erişip interaktiviteyi arttırmak için kullanıyorum.

constructor tARMAN_WSDL.Create(AOwner: TComponent);
begin
 inherited;
 // Varsayalın (Default) Action Ekledim.
 With Actions.Add do
 begin
   Default  := True;
   Name     := 'DefaultHandler';
   PathInfo := '/';
   OnAction := ARMAN_DefaultHandlerAction;
 end;

 // Yeni bir Action Ekledim. Kodla ekledim açıklayıcı olsun istedim.
 With Actions.Add do
 begin
    Default    := False;
    Enabled    := True;
    MethodType := mtAny;
    Name       := 'R01_Resim';
    PathInfo   := 'Resim_01';
    OnAction   := Resim_01_Action;
 end;
end;

procedure tARMAN_WSDL.ARMAN_DefaultHandlerAction(Sender: TObject;
 Request: TWebRequest; Response: TWebResponse; var Handled: Boolean);
Var
 strMesaj : String;
begin
//  Handled := True;
 if Assigned( xWSDLHelper.OnWebCagriGeldi ) then
 begin
   xWSDLHelper.OnWebCagriGeldi( sender, Request, Response );
 end else
 begin
   strMesaj := '<html>'
             + '<meta http-equiv=Content-Type content="text/html; charset=Windows-1254">'
             + '<body>'
             + 'Merhaba.'                                + '</br>'
             + '<font color="red">Muharrem ARMAN</font>' + '</br>'
             + 'WebService TEST...'                      + '</br>'
             + '<img src="' + String(Request.URL) + 'Resim_01">' + '</br>'
             ;

   if String(Request.Host) = String(Request.RemoteAddr)
     then strMesaj := strMesaj + 'Beni şu IP''den çağırdınız : '+ String(Request.Host) + '</br>'
     else strMesaj := strMesaj + 'Beni şu DOMAIN ile çağırdınız : '+ String(Request.Host) + '</br>';

   strMesaj := strMesaj + 'Sizin IP Adresiniz : '              + String(Request.RemoteAddr) + '</br>'
                        + '</body></html>';
   Response.Content     := strMesaj;
 end;
end;

procedure tARMAN_WSDL.Resim_01_Action(Sender: TObject; Request: TWebRequest;
 Response: TWebResponse; var Handled: Boolean);
begin
 Handled := True;
 // Response edilirken HTML içerisinde "Resim_01" kullanılan yerlerde
 // bu Action devreye girererek daha önce belirlediğimiz resmi yollar...
 ResimGonder( TResourceStream.Create(HInstance, Format('img_%.2d', [1]), RT_RCDATA), Response );
end;

 
function tARMAN_WSDL.ResimGonder( ResStream:TResourceStream; Response: TWebResponse ): Boolean;
begin
 try
   ResStream.Position     := 0;
   Response.ContentStream := ResStream;
   Response.ContentType   := 'image/jpeg';
   Response.SendResponse;
   Result := True;
 //Dikkat: FileStream FREE edilmeyecek çünkü yayındayız...
 except
   on E: Exception do begin
     Response.Content := '<html><body>Bir hata ile karşılaşıldı...' +
       E.ClassName + ': ' + E.Message + '</body></html>';
     Result := False;
   end;
 end;
end;
Üstadım, teşekkür ederim ilginize; ancak maalesef, yapamadım.
Kodlarım şu şekilde
procedure TWebModule1.WebModule1DefaultHandlerAction(Sender: TObject;
Request: TWebRequest; Response: TWebResponse; var Handled: Boolean);
var
strMesaj : String;
begin
strMesaj := '<html>'
+ '<meta charset="UTF-8">'
+ '<body>'
+ '<img src="'+Request.URL+'/resimyolla">' + '</br>';
strMesaj := strMesaj+'</body></html>';
Response.Content:= strMesaj;
end;
procedure TWebModule1.WebModule1resimyollaAction(Sender: TObject;
Request: TWebRequest; Response: TWebResponse; var Handled: Boolean);
begin
Handled := True;
ResimGonder(TResourceStream.Create(HInstance, 'r1.jpg', RT_RCDATA), Response );
end;

procedure TWebModule1.ResimGonder( ResStream:TResourceStream; var Response: TWebResponse );//: Boolean;
begin
try
ResStream.Position := 0;
Response.ContentStream := ResStream;
Response.ContentType := 'image/jpeg';
Response.SendResponse;
except
on E: Exception do begin
Response.Content := '<html><body>Bir hata ile karşılaşıldı...' +
E.ClassName + ': ' + E.Message + '</body></html>';
end;
end;
end;

ve oluşan HTML şu şekilde oluyor:
<html><meta charset="UTF-8"><body><img src="/resimyolla"></br></body></html>

Anlayacağınız, stand alone bir web projesi düşünüyorum ve exe dosya ile aynı klasörde bulunan r1.jpg dosyasını sayfamda göstermek istiyorum.
Daha önce IIS kullanarak yaptım, yani onda sorun yok; ancak IIS kullanmak istemiyorum, bu işleri stand alone proje ile yapmak istiyorum.
Merhaba

  1. Delphi ile örnek bir WebServer Application oluşturun.
  2. Resminizi aşağıdaki şekilde RC dosyası içerisinden refere ederek projenize ekleyin. 
    RES.RC dosyası içeriği
    Kod:
    r1      RT_RCDATA  r1.jpg
  3. Aşağıdaki kodu WebModule unitinizde oluşturun
    procedure TWebModule1.WebModuleCreate(Sender: TObject);
    begin
      With TWebModule(Sender).Actions.Add do begin
        Default    := False;
        Enabled    := True;
        MethodType := mtAny;
        Name       := 'r1';
        PathInfo   := 'r1.jpg';
        OnAction   := Resim_01_Action;
      end;
    end;
    
    procedure TWebModule1.Resim_01_Action(Sender: TObject; Request: TWebRequest;
     Response: TWebResponse; var Handled: Boolean);
    begin
      Handled := True;
      // Response edilirken HTML içerisinde "Resim_01" kullanılan yerlerde
      // bu Action devreye girererek daha önce belirlediğimiz resmi yollar...
      ResimGonder( TResourceStream.Create( HInstance, TWebActionItem(Sender).Name, PChar('RT_RCDATA') ), Response );
    end;
    
    function TWebModule1.ResimGonder( ResStream:TResourceStream; Response: TWebResponse ): Boolean;
    begin
      try
        ResStream.Position     := 0;
        Response.ContentStream := ResStream;
        Response.ContentType   := 'image/jpeg';
        Response.SendResponse;
        Result := True;
      //Dikkat: FileStream FREE edilmeyecek çünkü yayındayız...
      except
        on E: Exception do begin
          Response.Content := '<html><body>Bir hata ile karşılaşıldı...' +
            E.ClassName + ': ' + E.Message + '</body></html>';
          Result := False;
        end;
      end;
    end;
    
    
  4. Projenizi çalıştırıp bir Browser üzerinden http://localhost:8080/r1.jpg   yazın

Bu mesaj ekinden indirip deneyebilirsiniz.  Delphi 10.4.2 ile derlenmiştir.
Merhaba ,
Bu konuda ek bir bilgi de ben paylaşmak isterim ;
Eğer bir web broker uygulamasında üreteceğiniz HTML kodları mevcut sunucunuzdaki resim , css , js gibi dosyalara başvuruyorsa bunları rahatça kullanabilmek için TWebModule formunuzun üzerine bir adet TWebFileDispatcher nesnesi ekleyin ve bu nesnenin RootDirectory özelliğine dosyaların (resim,js , css vb..) tutulduğu diskteki klasörü belirtin (örn: c:\WebResimler\) artık HTML kodunuzun içinde kullanacağınız "src" ifadelerinin başvurusu bu klasör olacaktır.
<img src="resim.jpg"> şeklinde bir kullanımda resim.jpg dosyasının c:\WebResimler konumunda olması yeterlidir.
@vkamadan teşekkürler doğru noktaya temas etti. Unutmuşum söylemeyi, proje tek exe olduğu yapı için resource kullanımı faydalıdır.

Projede sürekli action oluşturmak olmaz, webfiledispatcher her actionu bir dosya çağrısı olarak ele alacaktır, dosya verilen path dahilinde varsa response edilecektir.

Bu verdiğim örnek aslında webfiledispatcher'in yaptığının manuel halidir.

Örneğin gelen path değerini illaki resource içinde aramak zorunda değilsiniz. Belirli bir yerel klasörden tResourcestream yerine tFilestream'e atıp  yollayabilir, kendi webfiledispstcherinizi tasarlamış olurdunuz. 

Buna gerek var mı? mekanizmayı kavramak için en az bir defa yapmak çok eğitici oluyor. Sonra konuyu delphi bileşenlerine havale edersiniz.
Çok teşekkür ederim, selamlar...

Çok teşekkür ederim, selamlar...