(15-05-2021, Saat: 02:29)CesuR Adlı Kullanıcıdan Alıntı: [ -> ]Emeğinize sağlık teşekkürler. Çok ilginç oldu bu, çünkü benim söylemimi bizzat Delphi kendiside belirtmişken sorunsuz çalışabiliyorsa bu çok sevindirici bir haber. Ama ben yinede tam anlamıyla çalışacağına şüpheli bakıyorum. Denediğiniz efektte çalışmış olabilir, ama yinede diğer animasyon ve efectleri deneyerek emin olmak lazım.
Merhaba,
Yanıldığınız nokta şu, Delphi bileşenleirini windowsa bağlı üretmiyor. Yani bir bileşen Windows DLL vs. dosyasına ihtiyaç duymuyor. Öyle olsaydı dediğiniz doğruydu. Siz geliştirmenizi FMX tarafında yapın yapmaya devam edin. Bilemezsiniz belki birgün Windows yerine Android kullanılmaya başlar normal makinelerde o zaman projenizde hazır olmuş olur. FMX tercih etmemek sanırım kullanılan 3.parti bileşenlerin fazla olmasından kaynaklı diye düşünüyorum.
İyi Çalışmalar.
Arkadaşlar cevaplar ve verdiğiniz örnekler için çok teşekkürler. Ama hep fmx platformu için örnekler verilmiş. @
ozcanm aynen dediğiniz gibi. FMX platformu tercih etmememin sebebi vcl tarafında çok fazla componenet kullanmış olmam. Özellikle devexpress yoğun şekilde kullanıyorum. Sanırım görsel tasarımları vcl ile geliştiremeyeceğiz.
Peki şöyle birşey yapılabilirmi. Özellikle konunun uzmanı hocalarıma soruyorum Login formu fmx ile yapıp diğer formları vcl ile geliştirilemezmi. Yani bi hibrit uygulama gibi?
(15-05-2021, Saat: 13:47)tuna Adlı Kullanıcıdan Alıntı: [ -> ]Arkadaşlar cevaplar ve verdiğiniz örnekler için çok teşekkürler. Ama hep fmx platformu için örnekler verilmiş. @ozcanm aynen dediğiniz gibi. FMX platformu tercih etmememin sebebi vcl tarafında çok fazla componenet kullanmış olmam. Özellikle devexpress yoğun şekilde kullanıyorum. Sanırım görsel tasarımları vcl ile geliştiremeyeceğiz.
Peki şöyle birşey yapılabilirmi. Özellikle konunun uzmanı hocalarıma soruyorum Login formu fmx ile yapıp diğer formları vcl ile geliştirilemezmi. Yani bi hibrit uygulama gibi?
DLL form örneklerine bir bakın hızlıca, yapamaz iseniz buradan destek olmaya çalışalım.
Başlığı bir süredir izliyorum, VCL yakasında da yapabileceğiniz çok şey var.
* FMX, bir platform çözümü olduğundan kullanıcısına kolaylık sunuyor o bakımdan önerilerde öncelikli.
* VCL ortamında da bir kod ile ekranın önce kopyasını alıp, alınan bu resmi başka bir kod ile blur hale getirebilir, başka bir kod grubu ile üzerine login editbox vb. dinamik olarak yerleştirebilir kullanıcı erişimini görsel destekle kontrol edebilirsiniz.
* Aşağıdaki örnek formu saklayıp ekran kopyası almayı, sonra bu ekran kopyasının blur edilmiş ( buzlu cam gibi ) halini elde etmeyi sağlıyor.
* Size bu resmi always on top özellikli tam ekran form ile kullanıp login işlemini yapmak kalıyor.
function GetScreenShot: TBitmap;
var
Desktop: HDC;
begin
Result := TBitmap.Create;
Desktop := GetDC(0);
try
try
Result.PixelFormat := pf24bit;
Result.Width := Screen.Width;
Result.Height := Screen.Height;
BitBlt(Result.Canvas.Handle, 0, 0, Result.Width, Result.Height, Desktop, 0, 0, SRCCOPY);
Result.Modified := True;
finally
ReleaseDC(0, Desktop);
end;
except
Result.Free;
Result := nil;
end;
end;
procedure Blur( aSource:TBitmap; aFactor: Word = 1 );
var
x, y : integer;
tline,
mline,
bline : PByteArray;
begin
while aFactor > 0 do
begin
for y := 1 to aSource.Height - 2 do
begin
tline := aSource.ScanLine[y-1];
mline := aSource.ScanLine[y];
bline := aSource.ScanLine[y+1];
for x := 1 to aSource.Width - 2 do
begin
mline^[x*3] := (mline^[x*3 - 3] + mline^[x*3 + 3] +
tline^[x*3 - 3] + tline^[x*3 + 3] + tline^[x*3] +
mline^[x*3 - 3] + mline^[x*3 + 3] + mline^[x*3]) div 8;
mline^[x*3+1] := (mline^[x*3 - 2] + mline^[x*3 + 4] +
tline^[x*3 - 2] + tline^[x*3 + 4] + tline^[x*3+1] +
mline^[x*3 - 2] + mline^[x*3 + 4] + mline^[x*3+1]) div 8;
mline^[x*3+2] := (mline^[x*3 - 1] + mline^[x*3 + 5] +
tline^[x*3 - 1] + tline^[x*3 + 5] + tline^[x*3+2] +
mline^[x*3 - 1] + mline^[x*3 + 5] + mline^[x*3+2]) div 8;
end;
end;
dec(aFactor);
end;
end;
uygulama :
procedure TForm1.BitBtn1Click(Sender: TObject);
var
LBitmap: TBitmap;
begin
Self.Left := -1 * (Self.Left + self.Width);
LBitmap := GetScreenShot();
Self.Left := -1 * (Self.Left + self.Width);
try
Blur( LBitmap, 10 );
Image1.Picture.Graphic := LBitmap;
finally
FreeAndNil( LBitmap );
end;
end;
@
mrmarman Hocam çok teşekkür ederim. Değişik bir fikir verdiniz. Bunu uygulayacağım.
@
ozcanm Hocam dll form olarak fmx i hiç düşünmemiştim. Bunu da deneyeceğim. Takıldığım yer olursa sizlere yine danışırım.
Herkese çok teşekkürler.
Merhaba.
* Devam ettirmek isterseniz, size örnekleyim derken şöyle bir basit sınıf başlangıcı oluşmuştu. Boşa gitmesin diye proje halinde paylaşayım dedim.
Uygulama Şekli
Var
FLoginFull : tFullScreenLoginForm;
procedure TForm1.FormCreate(Sender: TObject);
begin
LoginFormHazirla();
ReportMemoryLeaksOnShutdown := true;
end;
procedure TForm1.LoginFormHazirla;
var
ImgFile : String;
begin
Image1.Align := alClient;
ImgFile := ExtractFilePath(ParamStr(0)) + 'LoginUser.jpg';
Image2.Picture.LoadFromFile( ImgFile );
FLoginFull := tFullScreenLoginForm.Create;
try
FLoginFull.LoginScreen( self, Image1.Picture.Bitmap );
FLoginFull.RoundImage ( Image2.Picture.Graphic );
FLoginFull.CenterImage( Image2, self );
finally
FLoginFull.Free;
end;
Edit1.Width := Image2.Width * 2;
Edit1.Left := (self.Width - Edit1.Width) div 2;;
Edit1.Top := Image2.Top + Image2.Height + 20;
BitBtn1.Left := (self.Width - BitBtn1.Width) div 2;;
BitBtn1.Top := Edit1.Top + Edit1.Height + 10;
BitBtn1.Height := Edit1.Height + 10;
BitBtn2.Left := (self.Width - BitBtn2.Width) div 2;
BitBtn2.Top := BitBtn1.Top + BitBtn1.Height + 20;
Edit1.Text := '';
end;
Helper Unit
Kod:
unit LoginFullScreenU;
interface
Uses WinApi.Windows, System.SysUtils, VCL.Graphics, VCL.Forms, VCL.ExtCtrls, VCL.Controls;
Type
tFullScreenLoginForm = Class( TObject )
private
procedure Blur(aSource: TBitmap; aFactor: Word = 1 );
function GetScreenShot: TBitmap;
public
constructor Create;
destructor Destroy; override;
procedure RoundImage ( aGraphic: TGraphic );
procedure LoginScreen( aForm: TForm; aFormImage: TBitmap);
procedure CenterImage( aImage: TImage; aForm: TForm );
End;
implementation
{ tFullScreenLoginForm }
constructor tFullScreenLoginForm.create;
begin
inherited;
end;
destructor tFullScreenLoginForm.destroy;
begin
inherited;
end;
procedure tFullScreenLoginForm.LoginScreen( aForm: TForm; aFormImage: TBitmap );
const
LBlurFactor = 3;
var
LBitmap : TBitmap;
begin
aForm.StyleElements := [];
aForm.BorderStyle := bsNone;
aForm.FormStyle := fsNormal; //fsStayOnTop;
aForm.DoubleBuffered := true;
aForm.Left := 0;
aForm.Top := 0;
aForm.Width := Screen.Width;
aForm.Height := Screen.Height;
LBitmap := GetScreenShot();
try
Blur( LBitmap, LBlurFactor );
aFormImage.Assign( LBitmap );
finally
FreeAndNil( LBitmap );
end;
aForm.WindowState := TWindowState.wsMaximized;
end;
function tFullScreenLoginForm.GetScreenShot: TBitmap;
var
Desktop: HDC;
begin
Result := TBitmap.Create;
Desktop := GetDC(0);
try
try
Result.PixelFormat := pf24bit;
Result.Width := Screen.Width;
Result.Height := Screen.Height;
BitBlt(Result.Canvas.Handle, 0, 0, Result.Width, Result.Height, Desktop, 0, 0, SRCCOPY);
Result.Modified := True;
finally
ReleaseDC(0, Desktop);
end;
except
Result.Free;
Result := nil;
end;
end;
procedure tFullScreenLoginForm.Blur( aSource:TBitmap; aFactor: Word = 1 );
var
x, y : integer;
tline,
mline : System.SysUtils.PByteArray;
begin
while aFactor > 0 do
begin
for y := 1 to aSource.Height - 2 do
begin
tline := aSource.ScanLine[y-1];
mline := aSource.ScanLine[y ];
for x := 1 to aSource.Width - 2 do
begin
mline^[x*3] := (mline^[x*3 - 3] + mline^[x*3 + 3] +
tline^[x*3 - 3] + tline^[x*3 + 3] + tline^[x*3] +
mline^[x*3 - 3] + mline^[x*3 + 3] + mline^[x*3]) div 8;
mline^[x*3+1] := (mline^[x*3 - 2] + mline^[x*3 + 4] +
tline^[x*3 - 2] + tline^[x*3 + 4] + tline^[x*3+1] +
mline^[x*3 - 2] + mline^[x*3 + 4] + mline^[x*3+1]) div 8;
mline^[x*3+2] := (mline^[x*3 - 1] + mline^[x*3 + 5] +
tline^[x*3 - 1] + tline^[x*3 + 5] + tline^[x*3+2] +
mline^[x*3 - 1] + mline^[x*3 + 5] + mline^[x*3+2]) div 8;
end;
end;
dec(aFactor);
end;
end;
procedure tFullScreenLoginForm.RoundImage( aGraphic: TGraphic );
var
tmp, bmp : TBitmap;
Rhandle : HRGN;
R : TRect;
begin
bmp := TBitmap.Create;
tmp := TBitmap.Create;
try
bmp.Assign( aGraphic );
R := bmp.Canvas.ClipRect;
tmp.Width := bmp.Width;
tmp.Height := bmp.Height;
Rhandle := CreateRoundRectRgn( 0, 0, tmp.Width, tmp.Height, tmp.Width, tmp.Height);
tmp.Height := R.Bottom - R.Top;
tmp.Width := R.Right - R.Left;
tmp.Canvas.Brush.Color :=clRed;
tmp.Canvas.FillRect( tmp.Canvas.ClipRect );
SelectclipRgn(tmp.Canvas.Handle, rHandle);
tmp.Canvas.Draw(0, 0, bmp);
deleteObject(Rhandle);
tmp.Canvas.Brush.Style := bsClear;
tmp.TransparentColor := clRed;
tmp.Transparent := True;
aGraphic.Assign( tmp );
finally
FreeAndNil(bmp);
FreeAndNil(tmp);
end;
end;
procedure tFullScreenLoginForm.CenterImage( aImage: TImage; aForm: TForm );
Var
LImageWH : Integer;
begin
LImageWH := aForm.Width div 9;
aImage.Transparent := true;
aImage.AutoSize := False;
aImage.Proportional := True;
aImage.Center := True;
aImage.Stretch := True;
aImage.Anchors := [];
aImage.Width := LImageWH;
aImage.Height := LImageWH;
aImage.Left := ( aForm.Width - LImageWH ) div 2;
aImage.Top := ( aForm.Height - LImageWH ) div 3;
end;
end.

