Delphi Can

Orjinalini görmek için tıklayınız: Konum izni Requestpermissions
Şu anda (Arşiv) modunu görüntülemektesiniz. Orjinal Sürümü Görüntüle internal link
Merhaba arkadaşlar,

Delphi 12 de Android Konum izni Requestpermissions kodu verebilecek var mı?

Delphi 10.4 için elimde bir kod var 12 ile uyum sağlamadı

const
    PermissionAccessFineLocation = 'android.permission.ACCESS_FINE_LOCATION';
begin
{$IFDEF ANDROID}
 PermissionsService.RequestPermissions([PermissionAccessFineLocation],
     procedure(const APermissions :TArray<string>; const AGrantResults: TArray<TPermissionStatus>)
       begin
         if (length (AGrantResults) = 1) and ( AGRantResults[0]=TPermissionStatus.Granted)
           then LocationSensor1.Active := cbSensorAc.isChecked
         else
           begin
           cbSensorAc.IsChecked := False;
           ShowMessage('Konum izni verilmediği için program düzgün çalışmaz');
           end;

end);
{$ELSE}
LocationSensor1.Active := cbSensorAc.IsChecked;
{$ENDIF}
Direk çalışan kodlarımı yolluyorum.. kendinize göre uyarlarsınız..


{$IFDEF ANDROID}
 TThread.CreateAnonymousThread(
   procedure
   begin
     PermissionsService.RequestPermissions
       ([JStringToString(TJManifest_permission.JavaClass.ACCESS_NETWORK_STATE),
        JStringToString(TJManifest_permission.JavaClass.READ_EXTERNAL_STORAGE),
        JStringToString(TJManifest_permission.JavaClass.WRITE_EXTERNAL_STORAGE),
        JStringToString(TJManifest_permission.JavaClass.CAMERA),
        JStringToString(TJManifest_permission.JavaClass.READ_PHONE_STATE),
        JStringToString(TJManifest_permission.JavaClass.INTERNET)],
       procedure(const APermissions: TClassicStringDynArray;
         const AGrantResults: TClassicPermissionStatusDynArray)
       begin
         if (AGrantResults[0] = TPermissionStatus.Granted) then
           and_per := 0
         else
         begin
           Showmessage('Lütfen Yetkileri Veriniz..');
           and_per := 1
         end;
       end);
   end).Start;


{$ENDIF}
(07-03-2025, Saat: 22:12)mcuyan Adlı Kullanıcıdan Alıntı: [ -> ]Direk çalışan kodlarımı yolluyorum.. kendinize göre uyarlarsınız..


{$IFDEF ANDROID}
 TThread.CreateAnonymousThread(
   procedure
   begin
     PermissionsService.RequestPermissions
       ([JStringToString(TJManifest_permission.JavaClass.ACCESS_NETWORK_STATE),
        JStringToString(TJManifest_permission.JavaClass.READ_EXTERNAL_STORAGE),
        JStringToString(TJManifest_permission.JavaClass.WRITE_EXTERNAL_STORAGE),
        JStringToString(TJManifest_permission.JavaClass.CAMERA),
        JStringToString(TJManifest_permission.JavaClass.READ_PHONE_STATE),
        JStringToString(TJManifest_permission.JavaClass.INTERNET)],
       procedure(const APermissions: TClassicStringDynArray;
         const AGrantResults: TClassicPermissionStatusDynArray)
       begin
         if (AGrantResults[0] = TPermissionStatus.Granted) then
           and_per := 0
         else
         begin
           Showmessage('Lütfen Yetkileri Veriniz..');
           and_per := 1
         end;
       end);
   end).Start;


{$ENDIF}
Teşekkürler üstadım, deneyeceğim
estafrullah.. olur olur ama.. bi problem çıkarsa yazarsınız yine
(07-03-2025, Saat: 23:00)mcuyan Adlı Kullanıcıdan Alıntı: [ -> ]estafrullah.. olur olur ama.. bi problem çıkarsa yazarsınız yine

Teşekkürler, bu kodu deneyince telefonda program açılırken beyaz ekranda kalıp kitleniyor.
Merhaba,

Delphi 12.2 sürümünde çalışan erişim izni yapısı aşağıdadır.

uses kısmına :
  System.Permissions,
{$IF DEFINED(ANDROID)}
 Androidapi.Helpers,
 Androidapi.JNI.Os,
{$ENDIF}

procedure TForm1.Permission;
{$IF DEFINED(ANDROID)}
var
 F2, F3, F4, F5, F6, F7, F8: string;
{$ENDIF}
begin
{$IF DEFINED(ANDROID)}
 F2 := JStringToString(TJManifest_permission.JavaClass.CAMERA);
 F3 := JStringToString(TJManifest_permission.JavaClass.ACCESS_FINE_LOCATION);
 F4 := JStringToString(TJManifest_permission.JavaClass.CALL_PHONE);
 F5 := JStringToString(TJManifest_permission.JavaClass.READ_MEDIA_AUDIO);
 F6 := JStringToString(TJManifest_permission.JavaClass.READ_MEDIA_IMAGES);
 F7 := JStringToString(TJManifest_permission.JavaClass.READ_MEDIA_VIDEO);
 F8 := JStringToString(TJManifest_permission.JavaClass.POST_NOTIFICATIONS);

 PermissionsService.RequestPermissions([F2, F3, F4, F5, F6, F7, F8], PermissionRequestResult, nil);
{$ENDIF}
end;

procedure TForm1.PermissionRequestResult(Sender: TObject; const APermissions: TClassicStringDynArray; const AGrantResults: TClassicPermissionStatusDynArray);
{$IF DEFINED(ANDROID)}
var
 i: integer;
{$ENDIF}
begin

{$IF DEFINED(ANDROID)}
 for I := 0 to Length(AGrantResults) - 1 do
 begin
   if AGrantResults[i] <> TPermissionStatus.Granted then
   begin
     case I of
       0:
         begin
           showmessage('Kamera iznini reddettiniz! Uygulamanın bazı özelliklerinin çalışabilmesi için uygulama ayarlarından izin veriniz.');
         end;
       1:
         begin
           showmessage('Konum iznini reddettiniz! Uygulamanın bazı özelliklerinin çalışabilmesi için uygulama ayarlarından izin veriniz.');
         end;
       2:
         begin
           showmessage('Telefon iznini reddettiniz! Uygulamanın bazı özelliklerinin çalışabilmesi için uygulama ayarlarından izin veriniz.');
         end;
       3:
         begin
           showmessage('Medya medya iznini reddettiniz! Uygulamanın bazı özelliklerinin çalışabilmesi için uygulama ayarlarından izin veriniz.');
         end;
       4:
         begin
           showmessage('Medya iznini reddettiniz! Uygulamanın bazı özelliklerinin çalışabilmesi için uygulama ayarlarından izin veriniz.');
         end;
       5:
         begin
           showmessage('Medya iznini reddettiniz! Uygulamanın bazı özelliklerinin çalışabilmesi için uygulama ayarlarından izin veriniz.');
         end;
       6:
         begin
           showmessage('Bildirim iznini reddettiniz! Uygulamanın bazı özelliklerinin çalışabilmesi için uygulama ayarlarından izin veriniz.');
         end;
     end;
   end;
 end;
{$ENDIF}
end;


Kullanımı :

procedure TForm1.Button1Click(Sender: TObject);
begin
 Permission;
end;