Delphi Can

Orjinalini görmek için tıklayınız: Delphi ile SQL server bağlantı hatası yakalama
Şu anda (Arşiv) modunu görüntülemektesiniz. Orjinal Sürümü Görüntüle internal link
Sayfalar: 1 2 3
(02-11-2025, Saat: 19:04)Under Adlı Kullanıcıdan Alıntı: [ -> ]Merhabalar arkadaşlar;

Delphi 7 ile geliştirdiğim SERVER<>CLIENT yapıdaki uygulamam ağ hatası ile karşılaşınca Microsoft SQL server ile bağlantı koptuğu için doğal olarak hataya düşüyor.
Bazen network hataları, bazen ise kullanıcının bilgisayarı uyku moduna geçtiği için networkü kapatması nedeniyle bu hataları alıyorum.

Uygulamamda DataModule içinde bulunan ADOConnetion kullanıyorum ve tüm diğer ADO bileşenlerim bu ADOConnection üzerinden veritabanına bağlanıyor.

Hata sonrası kullanıcılar mecburen uygulamayı kapatıp açmak zorunda kalıyorlar.

Ben şunu yapmak istiyorum:

Bağlantı hatası durumunda ADOConnection bağlanmayı tekrar denesin, bağlanamıyorsa kullanıcıya bilgi versin.

en sağlıklı nasıl bir çözüm üretebiliriz? 

bu konuda yarımcı olabilirseniz sevinirim, şimdiden teşekkürlerimle.


Buradaki çözümü inceleyebilirsiniz (StackOverflow'daki bir çözümü incelerken mutlaka sorunun ve cevapların altındaki yorumları da okuyun):
database - How to resume/retry a broken TADOConnection across the application? - Stack Overflow

Procedure TDM.GetCommandResult_Conn(CText:String;Connection : TAdoConnection);
var Ado_Ds_Tmp:TAdoCommand;
Begin
   Ado_Ds_Tmp:=TAdoCommand.Create(self);
   try
     Ado_Ds_Tmp.Connection:=Connection;
     Ado_Ds_Tmp.ParamCheck := False;
     Ado_Ds_Tmp.CommandText:=CText;
     try
       Ado_Ds_Tmp.Execute;
     except
       DM.RaiseExceptionCreate('Error ! Command, ('+StrToList(CText, ' ')[0]+')');
     end;
   finally
     Ado_Ds_Tmp.Destroy;
   end;
end;

procedure TDM.ADOConnection1WillExecute(Connection: TADOConnection;
 var CommandText: WideString; var CursorType: TCursorType;
 var LockType: TADOLockType; var CommandType: TCommandType;
 var ExecuteOptions: TExecuteOptions; var EventStatus: TEventStatus;
 const Command: _Command; const Recordset: _Recordset);
var
  ErrorLogFileName : string;
  ErrorFile : TextFile;
  ErrorData : string;
  Msg : String;
begin
 try
   if (CommandText<>ConnectionTestString) then begin
     DM.GetCommandResult_Conn(ConnectionTestString, Connection);
   end;
 except
   try
     try
       Connection.Connected := False;
     except
     end;
     try
       Connection.ConnectionString := AdoConnectionString;
       Connection.Mode:=cmShareDenyNone;
     finally
       try
         Connection.Connected := True;
         // If you wanna log for frequency 
         ErrorLogFileName := ChangeFileExt(Application.ExeName,'.error.log');
         AssignFile(ErrorFile, ErrorLogFileName);
         if FileExists(ErrorLogFileName) then
           Append(ErrorFile)
         else
           Rewrite(ErrorFile);
         try
           ErrorData := Format('%s : %s : %s (%s / %s)',[DateTimeToStr(Now), 'Disconnected but we reconnect.', '', 'UserName : '+DBUser, 'Client : '+GetComputerNetName]);
           WriteLn(ErrorFile,ErrorData);
         finally
           CloseFile(ErrorFile)
         end;
       except
         DM.RaiseExceptionCreate('ReConnection Failed!');
       end;
     end;
   except
   end;
 end;
end;

(02-11-2025, Saat: 19:04)Under Adlı Kullanıcıdan Alıntı: [ -> ]Merhabalar arkadaşlar;

Delphi 7 ile geliştirdiğim SERVER<>CLIENT yapıdaki uygulamam ağ hatası ile karşılaşınca Microsoft SQL server ile bağlantı koptuğu için doğal olarak hataya düşüyor.
Bazen network hataları, bazen ise kullanıcının bilgisayarı uyku moduna geçtiği için networkü kapatması nedeniyle bu hataları alıyorum.

Uygulamamda DataModule içinde bulunan ADOConnetion kullanıyorum ve tüm diğer ADO bileşenlerim bu ADOConnection üzerinden veritabanına bağlanıyor.

Hata sonrası kullanıcılar mecburen uygulamayı kapatıp açmak zorunda kalıyorlar.

Ben şunu yapmak istiyorum:

Bağlantı hatası durumunda ADOConnection bağlanmayı tekrar denesin, bağlanamıyorsa kullanıcıya bilgi versin.

en sağlıklı nasıl bir çözüm üretebiliriz? 

bu konuda yarımcı olabilirseniz sevinirim, şimdiden teşekkürlerimle.

Bu çözüm de hatayı (exception'ı) nasıl yakalayacağınızı anlatıyor:

delphi - How can I detect that a TadoConnection lost the communication with the server? - Stack Overflow


(*
Source - https://stackoverflow.com/questions/2289...ect=1&lq=1
Posted by jachguate
Retrieved 11/4/2025, License - CC-BY-SA 4.0
*)

uses
 ComObj;

procedure TForm2.ApplicationEvents1Exception(Sender: TObject; E: Exception);
var
 EO: EOleException;
begin
 if E is EOLEException then
 begin
   EO := EOleException(E);
   //connection error (disconnected)
   if EO.ErrorCode = E_FAIL then
   begin
     try
       try
         ADOConnection1.Close;
       except
         ;
       end;
       ADOConnection1.Open;
       ShowMessage('Database connection failed and re-established, please retry!');
     except
       on E:Exception do
         ShowMessageFmt('Database connection failed permanently.  '
           + 'Please, retry later'#13'Error message: %s', [E.Message]);
     end;
   end
   else
     ShowMessage(E.Message + ' ' + IntToStr(EO.ErrorCode));
 end
 else
   ShowMessage(E.ClassName + #13 + E.Message);
end;
@csunguray çok çok tşk ederim,

kopuk bağlantı algılarken bu örneklerden faydalanacağım.
@csunguray ADO bağlantıdaki sorunu algılarken 15-20 sn. bekletiyor, gerçi ADO dışında farklı komponentlerle de denedim yine bekletiyor.
bu kadar uzun beklemeden bağlantı sorununu tespit etmek mümkün değil mi? siz ne düşünürsünüz bu konuda?
GPT nin cevabı:

Aşağıda Delphi 7 + ADO + SQL Server için bağlantı koptuğunda yeniden bağlanma ve uygulamayı kapatıp açmaya gerek kalmaması için kullanılan en güvenilir yaklaşımı adım adım anlatıyorum.

Temel Sorun
ADOConnection bağlantısı koptuğunda (network kesilmesi, bilgisayarın uykuya geçmesi, kablo çıkması vs.) ADO’nun iç durumu “bozuluyor”.
ADO otomatik olarak yeniden bağlanmaz ve bu nedenle bütün Query/Command bileşenleri hataya düşer. Bu ADO’nun bir “eksikliğidir”.
Dolayısıyla manuel olarak yeniden bağlanma işlemi yazmanız gerekir.

En Sağlıklı Çözüm: "Connection Health Check" + "Auto-Reconnect"

Adım 1 — ADOConnection için bir fonksiyon yazın
DataModule’ünüze şu fonksiyonu ekleyin:

function TDM.CheckAndReconnect: Boolean;
begin
 Result := True;

 try
   // Bağlı değilse bağlan
   if not ADOConnection1.Connected then
     ADOConnection1.Connected := True;

   // Bağlantı bozulmuş mu diye test sorgusu çalıştır
   ADOConnection1.Execute('SELECT 1');
 except
   on E: Exception do
   begin
     Result := False;

     // Yeniden bağlanmayı deneyelim
     try
       ADOConnection1.Connected := False;
       Sleep(500);   // küçük bekleme
       ADOConnection1.Connected := True;

       // Bağlantı tekrar test edilir
       ADOConnection1.Execute('SELECT 1');
       Result := True;
     except
       Result := False;
     end;
   end;
 end;
end;

Bu fonksiyon:
  1. Bağlantı kopmuş olsa bile önce bağlantıyı kapatır.
  2. Tekrar bağlanmayı dener.
  3. Mini test sorgusu ile bağlantıyı doğrular.

    Adım 2 — Tüm Query işlemlerinden önce bağlantı kontrolü


    ADOQuery/ADOCommand çalıştırmadan önce:
    if not DM.CheckAndReconnect then
    begin
     ShowMessage('Veritabanı bağlantısı sağlanamadı. Lütfen ağınızı kontrol edin.');
     Exit;
    end;
    

    Adım 3 — Global Exception Handling içinde de kontrol

    Formlarınızda veya proje dosyanızda:

    try
      if not DM.CheckAndReconnect then
       ShowMessage('Bağlantı kesildi. Yeniden bağlanılamadı.');
    except
     on E: EOleException do
     begin
       if Pos('communication', LowerCase(E.Message)) > 0 then
         DM.CheckAndReconnect;
     end;
    end;
    

    Adım 4 — Timeout ve ConnectionString ayarları

    ConnectionString'e şunu ekleyin:
    Connect Timeout=5;
    

    ADOConnection nesnesine:
    LoginPrompt := False;
    KeepConnection := True;
    

    Ek olarak:
    CommandTimeout := 10;
    ConnectionTimeout := 5;
    

    Uyku Modunda Bağlantı Kaybı Problemi
    Laptop uykuya geçince ağ kartı kapanır ve bağlantı mutlaka kopar.
    Bu nedenle uygulamanızda timer ile periyodik bağlantı kontrolü ekleyebilirsiniz:

    procedure TForm1.Timer1Timer(Sender: TObject);
    begin
     DM.CheckAndReconnect;
    end;
    

    Alternatif Olarak (Daha Dayanıklı): MARS / FireDAC / Zeos
    ADO eski bir teknoloji olduğu için bağlantı bozulunca çok kolay çöküyor.
    Eğer geleceğe dönük bir çözüm isterseniz:
    • FireDAC (Delphi XE4+)
    • ZeosLib (Delphi 7 ile uyumlu)
    • MARS-DGL (REST servisleri)
  4. ADO’ya göre çok daha stabil bağlantı yenileme mekanizmaları var.
  5. ✔️ Sonuç
    Bu yöntemle:
    • Ağ gidip gelse bile uygulamanız yeniden bağlanır.
    • Kullanıcı uygulamayı kapatmak zorunda kalmaz.
    • Uyku modundan geri geldiğinde bile bağlantı yeniden kurulur.


      Lütfen deneyip bilgi verebilir misiniz? Gerçekten işe yarayacak mı bende merak ettim.
deneyeceğim, ancak bunlar benim temel sorunum olan kopuk bağlantı algılama süresinin uzunluğu konusunda çözüm üretmiyor.
Öncekileri de kendisi önerdi ama, son fikri şu:
  • ConnectTimeout → ✔ ama kopma algılamasını çözmez
  • CommandTimeout → ✔ ama sadece long wait durumunda devreye göreceli girer
  • Reconnect → ✔ ama ADO geç algıladığı için işe geç yarar
Kullanıcı "geç algılıyor" diyorsa, bunun ADO tarafında bir çözümü yok.

Gerçek çözüm üç tanedir:
1) SQL Native Client provider kullanmak
2) Heartbeat timer eklemek (en garantili yöntem)
3) Modern bir DB bileşenine geçmek (Firedac / Zeos / UniDAC)


Bu şablon şu sorunları tamamen çözer:
✔ ADO’nun bağlantı kopmasını geç algılaması
✔ Kullanıcı sorgu çalıştırınca uzun donmalar
✔ Reconnect’in geç devreye girmesi
✔ Uyku modundan uyanınca hata vermesi
Bu modül POS sistemleri, barkodlu depo ERP, üretim otomasyonları gibi sürekli bağlantının kritik olduğu sistemlerde standarttır.


TAM ÇÖZÜM: DataModule (ADO) + Heartbeat + Auto-Reconnect
Aşağıdaki DataModule’u oluştur:

Bir TADOConnection

Bir TTimer (Heartbeat için)

Birkaç yardımcı fonksiyon

Timer’ın Interval = 5000 (5 saniye) yap.

Unit: DM.pas
unit DM;

interface

uses
 SysUtils, Classes, DB, ADODB, ExtCtrls, Windows;

type
 TDM = class(TDataModule)
   ADO: TADOConnection;
   HBTimer: TTimer;         // Heartbeat Timer
   procedure DataModuleCreate(Sender: TObject);
   procedure HBTimerTimer(Sender: TObject);
 private
   FIsConnected: Boolean;
   function TestConnection: Boolean;
   procedure TryReconnect;
 public
   function EnsureConnection: Boolean;
   property IsConnected: Boolean read FIsConnected;
 end;

var
 DM: TDM;

implementation

{$R *.dfm}

procedure TDM.DataModuleCreate(Sender: TObject);
begin
 // ACELE: ADO ayarları
 ADO.LoginPrompt := False;
 ADO.ConnectionTimeout := 5;
 ADO.CommandTimeout := 5;

 // PROVIDER ÖNEMLİ
 // ADO + SQL Native Client = hızlı kopukluk algılama
 ADO.ConnectionString :=
   'Provider=SQLNCLI11;' +
   'Server=SERVER_ADI;' +
   'Database=DB_ADI;' +
   'Uid=KULLANICI;' +
   'Pwd=SIFRE;' +
   'Connect Timeout=5;';

 FIsConnected := False;
 TryReconnect;      // ilk bağlantı girişimi

 HBTimer.Interval := 5000;  // 5 saniyede bir kalp atışı
 HBTimer.Enabled := True;
end;

Bağlantı Testi (Fast Detect)
function TDM.TestConnection: Boolean;
begin
 Result := False;
 try
   if not ADO.Connected then Exit(False);

   // Mini test sorgusu - SELECT 1 daha stabil
   ADO.Execute('SELECT 1');
   Result := True;
 except
   Result := False;
 end;
end;
Bu sorgu çok hızlıdır ve ağ kopukluğunu 1 saniye içinde algılar.


Reconnect Mekanizması
procedure TDM.TryReconnect;
begin
 try
   ADO.Connected := False;
   Sleep(200);
   ADO.Connected := True;

   FIsConnected := TestConnection;
 except
   FIsConnected := False;
 end;
end;


EnsureConnection (her sorgudan önce güvenli çağrı)

Uygulamada tüm ADOQuery’lerden önce bunu çağıracaksın.
function TDM.EnsureConnection: Boolean;
begin
 // bağlantı sağlam mı?
 if TestConnection then
 begin
   Result := True;
   Exit;
 end;

 // değilse reconnect dene
 TryReconnect;
 Result := FIsConnected;
end;

Kullanımı:
if DM.EnsureConnection then
 Query.Open
else
 ShowMessage('Bağlantı kurulamadı. Lütfen ağı kontrol edin.');


Heartbeat Timer — kopukluğu arka planda yakalar

Bu kritik bölüm sayesinde kullanıcı işlem yapmadan önce bağlantı tazelenmiş olur.
procedure TDM.HBTimerTimer(Sender: TObject);
begin
 if not TestConnection then
   TryReconnect;
end;

Heartbeat sayesinde:
  • Kullanıcı butona bastığında bağlantı zaten sağlanmış olur.
  • ADO hiçbir zaman 20–30 saniye beklemez.
  • Uyku modundan dönünce anında toparlar.
Bu DataModule Sana Ne Kazandırır?
✔ Kopma anında ADO’daki uzun beklemeler bitiyor
✔ Sistem kopukluğu 3–5 saniyede algılıyor (native client ile daha da hızlı)
✔ Bağlantı kendi kendine arka planda düzeliyor
✔ Kullanıcıya "program dondu" hissi gelmiyor
✔ Uygulamayı kapatıp açma ihtiyacı ortadan kalkıyor
Bu tam bir kurumsal seviye çözümdür.



Sizide boş yere uğraştırmak istemem ama "bu"nun ipiyle kuyuya inmek ister veya önerisini son kez denemek isterseniz, uzunca süren sohbetimizin bir kısmı böyle idi. Kolay gelsin.
ilginiz için tşk ederim öncelikle, evet doğru chatgpt ye tam güvenemiyoruz, yukarıdaki kodlar da yine ADO ya bağımlı olduğu için çözüm üretemez,
ChatGpt ADO dan bağımsız farklı bir öneri sundu, bu öneri bana mantıklı geldi, şöyleki;

✅ Delphi 7 – Aşırı Hızlı SQL Server TCP Port Testi (Indy ile)  1 saniyeden kısa sürede bağlantının kopukları tespit eder.

Kod:
uses
 IdTCPClient, IdGlobal;

function IsSqlServerAvailable(const Host: string; Port: Integer = 1433): Boolean;
var
 C: TIdTCPClient;
begin
 Result := False;
 C := TIdTCPClient.Create(nil);
 try
   C.Host := Host;
   C.Port := Port;
   C.ConnectTimeout := 800;  // 0.8 sn içinde cevap yoksa kopuk kabul edilir
   C.ReadTimeout := 800;

   try
     C.Connect;              // SQL Server çevrimdışı veya ağ kopuksa hemen hata verir
     Result := True;
     C.Disconnect;
   except
     Result := False;
   end;

 finally
   C.Free;
 end;
end;

nasıl kullanacağımı da yazdı Smile

Kod:
procedure TForm1.Timer1Timer(Sender: TObject);
begin
 if not IsSqlServerAvailable('192.168.1.10', 1433) then
 begin
   LabelStatus.Caption := 'SQL Bağlantısı koptu!';
   // Burada ADO bağlantısını kapatabilir veya yeniden bağlanmayı deneyebilirsin
 end
 else
   LabelStatus.Caption := 'SQL Bağlantısı aktif';
end;
deneyeceğim.

denedim ve işe yaradığını görüyorum, 1-2 sn içinde kopuk bağlantıyı algılıyor.
@Under  Sorununuzu halletmeniz güzel... Yalnız, benim anlayamadığım bir konuya tekrar şahit olduk. Aktif kullandığım 5 dil modeli de tutarlı değil, bazen inanılmaz çözümler sunarken, bazen neredeyse söyleneni anlayamıyorlar. Çok güzel bir "oturum" yakalamışsınız, sonuna kadar değerlendirin Smile
timer içine küçük bir sql komutu yaz try icinde gönder eger cevap geliyorsa zaden baglıdır gelmiyorsea istisnanın içinde tekrar baglanmayı deneyebilirsin ben öyle yapıyorum
(19-11-2025, Saat: 16:21)metemet Adlı Kullanıcıdan Alıntı: [ -> ]timer  içine  küçük bir sql komutu yaz   try  icinde gönder eger cevap  geliyorsa  zaden baglıdır gelmiyorsea istisnanın içinde  tekrar baglanmayı deneyebilirsin ben  öyle yapıyorum

bu yazdığın yöntem bağlantı kopuksa 15-20 sn bekletiyor, derdimiz de bu zaten.
Sayfalar: 1 2 3