![]() |
|
OrangeUI TakeFromPicture hataları - Baskı Önizleme +- Delphi Can (https://www.delphican.com) +-- Forum: Delphi (https://www.delphican.com/forumdisplay.php?fid=3) +--- Forum: Mobil Platform - FireMonkey (FMX) (https://www.delphican.com/forumdisplay.php?fid=7) +--- Konu Başlığı: OrangeUI TakeFromPicture hataları (/showthread.php?tid=4359) |
OrangeUI TakeFromPicture hataları - 41linea41 - 28-12-2019 Merhaba OrangeUI Takefrompicture sample üzerinden çalışma yapıyorum. Ama ilk seçenek kamerayı açma seçeneğini bir türlü yapamadım. Kamera açılmıyor. Standart Actionlist ile de denememde kameryı açamadın uses permission kkısmında kamera seçili olmasına rağmen. İkinci seçenek olan galeriden seçme işleminde ise seçilen foroğrafı alamadım.SkinFMXPicture ın içine seçili fotoyu nasıl atabilirim? Değerli fikirlerinizi duymak sterim. ![]() //convert pas to utf8 by ¥
unit TakePictureMenuFrame;
interface
uses
System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
uUIFunction,
uVersion,
uSkinItems,
uFuncCommon,
uLang,
uBaseLog,
uFrameContext,
uSkinFireMonkeyEdit,
uSkinFireMonkeyMemo,
uProcessNativeControlModalShowPanel,
FMX.Types, FMX.Graphics, FMX.Controls, FMX.Forms, FMX.Dialogs, FMX.StdCtrls,
uSkinFireMonkeyButton, uSkinFireMonkeyControl, uSkinFireMonkeyPanel,
uSkinFireMonkeyLabel, uSkinFireMonkeyImage, FMX.Controls.Presentation,
uSkinAnimator, uSkinFireMonkeyScrollControl, uSkinFireMonkeyVirtualList,
uSkinFireMonkeyListBox, FMX.MediaLibrary.Actions, System.Actions,
FMX.ActnList, FMX.StdActns, uSkinFireMonkeyCustomList, uSkinButtonType,
uSkinScrollControlType, uSkinCustomListType, uSkinVirtualListType,
uSkinListBoxType, uBaseSkinControl, uSkinPanelType;
type
THideMenuType=(hmtNone,hmtHasPicture);
TTakedPictureEvent=procedure(Sender:TObject;ABitmap:TBitmap) of object;
TFrameTakePictureMenu = class(TFrame,
IFrameChangeLanguageEvent,
IFrameHistroyReturnEvent)
pnlBackground: TSkinFMXPanel;
pnlBottom: TSkinFMXPanel;
lbMenu: TSkinFMXListBox;
scmaPopup: TSkinControlMoveAnimator;
ActionList: TActionList;
ActionTakePhotoFromLibrary: TTakePhotoFromLibraryAction;
ActionTakePhotoFromCamera: TTakePhotoFromCameraAction;
btnUseInIPadSetPosition: TSkinFMXButton;
procedure FrameResize(Sender: TObject);
procedure pnlBackgroundClick(Sender: TObject);
procedure ActionTakePhotoFromLibraryDidFinishTaking(Image: TBitmap);
procedure ActionTakePhotoFromCameraDidFinishTaking(Image: TBitmap);
procedure lbMenuClickItem(Sender: TSkinItem);
procedure scmaPopupAnimateEnd(Sender: TObject);
private
FRawBitmap: TBitmap;
HideMenuType:THideMenuType;
procedure TakePhotoFromCamera;
procedure TakePhotoFromAlbum;
{ Private declarations }
protected
procedure ChangeLanguage(ALangKind:TLangKind);
protected
function CanReturn:Boolean;
public
OnTakedPicture:TTakedPictureEvent;
procedure HideMenu;
procedure ShowMenu;
public
FrameHistroy:TFrameHistroy;
constructor Create(AOwner:TComponent);override;
destructor Destroy;override;
{ Public declarations }
end;
var
GlobalTakePictureMenuFrame:TFrameTakePictureMenu;
procedure CopyBitmap(ASrcBitmap:TBitmap;ADestBitmap:TBitmap);
implementation
uses uOgrenciDetay;
procedure CopyBitmap(ASrcBitmap:TBitmap;ADestBitmap:TBitmap);
begin
ADestBitmap.SetSize(ASrcBitmap.Width,ASrcBitmap.Height);
ADestBitmap.Canvas.BeginScene();
try
ADestBitmap.Canvas.Clear(0);
ADestBitmap.Canvas.DrawBitmap(
ASrcBitmap,
RectF(0,0,ASrcBitmap.Width,ASrcBitmap.Height),
RectF(0,0,ADestBitmap.Width,ADestBitmap.Height),
1
);
finally
ADestBitmap.Canvas.EndScene;
end;
end;
{$R *.fmx}
{ TFrameTakePictureMenu }
procedure TFrameTakePictureMenu.TakePhotoFromAlbum;
var
Image:TBitmap;
OpenDialog: TOpenDialog;
I: Integer;
begin
// uBaseLog.OutputDebugString('aa','');
{$IFDEF MSWINDOWS}
OpenDialog := TOpenDialog.Create(nil);
try
OpenDialog.Filter := TBitmapCodecManager.GetFilterString;
OpenDialog.Options:=OpenDialog.Options+[TOpenOption.ofAllowMultiSelect];
if OpenDialog.Execute then
begin
for I := 0 to OpenDialog.Files.Count-1 do
begin
Image:=TBitmap.CreateFromFile(OpenDialog.Files[I]);
ActionTakePhotoFromLibraryDidFinishTaking(Image);
uFuncCommon.FreeAndNil(Image);
end;
end;
finally
uFuncCommon.FreeAndNil(OpenDialog);
end;
{$ENDIF}
{$IFNDEF MSWINDOWS}
//btnUseInIPadSetPosition
ActionTakePhotoFromLibrary.ExecuteTarget(btnUseInIPadSetPosition);
{$ENDIF}
//{$IF DEFINED(IOS) or DEFINED(ANDROID)}
// ActionTakePhotoFromLibrary.ExecuteTarget(btnUseInIPadSetPosition);
// {$ENDIF}
end;
procedure TFrameTakePictureMenu.TakePhotoFromCamera;
var
Image:TBitmap;
OpenDialog: TOpenDialog;
I: Integer;
begin
// uBaseLog.OutputDebugString('拍照','');
//拍照
{$IFDEF MSWINDOWS}
OpenDialog := TOpenDialog.Create(nil);
try
OpenDialog.Filter := TBitmapCodecManager.GetFilterString;
OpenDialog.Options:=OpenDialog.Options+[TOpenOption.ofAllowMultiSelect];
if OpenDialog.Execute then
begin
for I := 0 to OpenDialog.Files.Count-1 do
begin
Image:=TBitmap.CreateFromFile(OpenDialog.Files[I]);
ActionTakePhotoFromLibraryDidFinishTaking(Image);
uFuncCommon.FreeAndNil(Image);
end;
end;
finally
uFuncCommon.FreeAndNil(OpenDialog);
end;
{$ENDIF}
{$IFNDEF MSWINDOWS}
try
ActionTakePhotoFromCamera.ExecuteTarget(Self);
except
on E:Exception do
begin
uBaseLog.HandleException(E,'ActionTakePhotoFromCamera.ExecuteTarget');
end;
end;
{$ENDIF}
{$IF DEFINED(IOS) or DEFINED(ANDROID)}
try
ActionTakePhotoFromCamera.ExecuteTarget(Self);
except
on E:Exception do
begin
uBaseLog.HandleException(E,'ActionTakePhotoFromCamera.ExecuteTarget');
end;
end;
{$ENDIF}
end;
procedure TFrameTakePictureMenu.ActionTakePhotoFromCameraDidFinishTaking(Image: TBitmap);
var
ScaleFactor: Single;
begin
if Image.Width > 1024 then
begin
ScaleFactor := Image.Width / 1024;
Image.Resize(Round(Image.Width / ScaleFactor), Round(Image.Height / ScaleFactor));
end;
// FRawBitmap.Assign(Image);
CopyBitmap(Image,FRawBitmap);
HideMenuType:=hmtHasPicture;
HideMenu;
end;
procedure TFrameTakePictureMenu.ActionTakePhotoFromLibraryDidFinishTaking(Image: TBitmap);
var
ScaleFactor: Single;
begin
if Image.Width > 1024 then
begin
ScaleFactor := Image.Width / 1024;
Image.Resize(Round(Image.Width / ScaleFactor), Round(Image.Height / ScaleFactor));
end;
// FRawBitmap.Assign(Image);
CopyBitmap(Image,FRawBitmap);
HideMenuType:=hmtHasPicture;
HideMenu;
end;
procedure TFrameTakePictureMenu.HideMenu;
begin
scmaPopup.GoForward;
end;
procedure TFrameTakePictureMenu.ShowMenu;
begin
//先隐藏原生控件
//设置Edit的ControlType,避免MessageBoxFrame被原生控件挡住
SetGlobalEditListAsStyleType;
SetGlobalMemoListAsStyleType;
ProcessNativeControlBeginModalShow;
Self.pnlBackground.Visible:=True;
Self.pnlBackground.Align:=TAlignLayout.alNone;
Self.pnlBackground.SetBounds(0,0,Width,Height);
Self.lbMenu.Width:=Width;
Self.pnlBackground.BringToFront;
scmaPopup.GoBackward;
end;
procedure TFrameTakePictureMenu.scmaPopupAnimateEnd(Sender: TObject);
begin
if Self.scmaPopup.DirectionType=adtForward then
begin
//隐藏弹出菜单结束
Self.pnlBackground.Visible:=False;
Self.Visible:=False;
//一定要放在隐藏WaitingFrame的后面
//还原所有的Edit的ControlType为Platform
RestoreGlobalEditListAsPlatformType;
RestoreGlobalMemoListAsPlatformType;
//先隐藏WaitingFrame,再还原,免得WaitingFrame被盖住
ProcessNativeControlEndModalShow;
HideFrame(Self,hfcttBeforeReturnFrame,ufsefNone);
ReturnFrame(Self);
case HideMenuType of
hmtHasPicture:
begin
if Assigned(OnTakedPicture) then
begin
OnTakedPicture(Self,FRawBitmap);
end;
end;
end;
end;
end;
function TFrameTakePictureMenu.CanReturn: Boolean;
begin
if Self.Visible then
begin
Result:=False;
HideMenu;
end
else
begin
//直接返回
Result:=True;
end;
end;
procedure TFrameTakePictureMenu.ChangeLanguage(ALangKind: TLangKind);
const
Langs_Button_Caption_Camera : array[Low(TLangKind)..High(TLangKind)] of string =
('Fotoğraf Çekin','Take Photo','');
Langs_Button_Caption_Album : array[Low(TLangKind)..High(TLangKind)] of string =
('Galeriden Seçin','Select From Album','');
// Langs_Button_Caption_Cancel : array[Low(TLangKind)..High(TLangKind)] of string =
// ('从相册选择','Select From Album','');
Langs_Button_Caption_CANCEL : array[Low(TLangKind)..High(TLangKind)] of string =
('Kapat','Cancel','');
begin
//翻译
Self.lbMenu.Properties.Items.FindItemByName('btnFoto').Caption:=Langs_Button_Caption_Camera[ALangKind];
Self.lbMenu.Properties.Items.FindItemByName('btnGaleri').Caption:=Langs_Button_Caption_Album[ALangKind];
Self.lbMenu.Properties.Items.FindItemByName('btnKapat').Caption:=Langs_Button_Caption_Cancel[ALangKind];
end;
constructor TFrameTakePictureMenu.Create(AOwner: TComponent);
begin
inherited;
FRawBitmap := TBitmap.Create(0, 0);
RecordSubControlsLang(Self);
TranslateSubControlsLang(Self);
end;
destructor TFrameTakePictureMenu.Destroy;
begin
uFuncCommon.FreeAndNil(FRawBitmap);
inherited;
end;
procedure TFrameTakePictureMenu.FrameResize(Sender: TObject);
begin
Self.pnlBackground.SetBounds(0,0,Width,Height);
Self.lbMenu.Width:=Width;
end;
procedure TFrameTakePictureMenu.lbMenuClickItem(Sender: TSkinItem);
begin
if TSkinItem(Sender).Name='btnFoto' then
begin
TakePhotoFromCamera;
end;
if TSkinItem(Sender).Name='btnGaleri' then
begin
TakePhotoFromAlbum;
end;
if TSkinItem(Sender).Name='btnKapat' then
begin
HideMenuType:=hmtNone;
HideMenu;
end;
end;
procedure TFrameTakePictureMenu.pnlBackgroundClick(Sender: TObject);
begin
OnTakedPicture:=nil;
HideMenuType:=hmtNone;
HideMenu;
end;
end.
Cvp: OrangeUI TakeFromPicture hataları - Fesih ARSLAN - 28-12-2019 Merhaba, Önce dilerseniz örnek uygulamayı görelim. OrangeUI'ın fotoğraf çekme veya galeriden bir fotoğraf alma Frame'ini (TFrameTakePictureMenu) nasıl kullanacağınızı öğrenmek için aşağıdaki işlem adımlarını takip edin. - Ana formdan bu Frame'i çağıracağınızı varsayıyorum. - Form üzerine bir adet TSkinFMXImage (name=imgDelphiCan) yerleştirin. - Ana formun Uses bölümüne aşağıdaki kütüphaneleri ekleyin. uses TakePictureMenuFrame, uUIFunction, FMX.Dialogs
{$IFDEF ANDROID}
, Androidapi.Helpers,
Androidapi.JNI.JavaTypes,
Androidapi.JNI.Os
{$ENDIF};
- Formun private alanında aşağıdaki tanımlamaları yapın. private FPermissionCamera, FPermissionReadExternalStorage, FPermissionWriteExternalStorage: string;- Formun OnCreate olayında sabit atamaları yapın. {$IFDEF ANDROID}
FPermissionCamera := JStringToString(TJManifest_permission.JavaClass.CAMERA);
FPermissionReadExternalStorage := JStringToString(TJManifest_permission.JavaClass.READ_EXTERNAL_STORAGE);
FPermissionWriteExternalStorage := JStringToString(TJManifest_permission.JavaClass.WRITE_EXTERNAL_STORAGE);
{$ENDIF}
- Frame'i göstereceğiniz bir butonun OnClick olayına aşağıdaki kodu yazın. Burada kamera kullanım ve dahili hafıza kullanım izinleri talep ediliyor ve izin verilip verilmediği kontrol ediliyor.PermissionsService.RequestPermissions([FPermissionCamera, FPermissionReadExternalStorage, FPermissionWriteExternalStorage], KamereVeGaleriIzinSonuclariniKontrolEt, DisplayRationale);- KamereVeGaleriIzinSonuclariniKontrolEt, DisplayRationale ve FotografAlindi() procedure'leri aşağıdadır. // Seçimliktir, nil de olabilir. Kullanıcı erişim izinlerinin gerekçeleri belirtilir.
procedure TForm1.DisplayRationale(Sender: TObject; const APermissions: TArray<string>; const APostRationaleProc: TProc);
var
I: Integer;
RationaleMsg: string;
begin
for I := 0 to High(APermissions) do
begin
if APermissions[I] = FPermissionCamera then
RationaleMsg := RationaleMsg + 'Fotoğraf çekmek için kamera erişim iznine ihtiyacımız var.' + SLineBreak
else if APermissions[I] = FPermissionReadExternalStorage then
RationaleMsg := RationaleMsg +
'Galeriye fotoğarf kaydetmek veya galeriden bir fotoğraf almak için dahili hafızaya erişim iznine ihtiyacımız var.';
end;
TDialogService.ShowMessage(RationaleMsg,
procedure(const AResult: TModalResult)
begin
APostRationaleProc;
end);
end;
procedure TForm1.KamereVeGaleriIzinSonuclariniKontrolEt(Sender: TObject; const APermissions: TArray<string>;
const AGrantResults: TArray<TPermissionStatus>);
begin
// Kamera kullanmak ve fotoğraf kaydetmek için: CAMERA, READ_EXTERNAL_STORAGE ve WRITE_EXTERNAL_STORAGE
if (Length(AGrantResults) = 3) and (AGrantResults[0] = TPermissionStatus.Granted) and
(AGrantResults[1] = TPermissionStatus.Granted) and (AGrantResults[2] = TPermissionStatus.Granted) then
begin
ShowFrame(TFrame(GlobalTakePictureMenuFrame), TFrameTakePictureMenu, Self, nil, nil, nil, Application, True, True,
ufsefNone);
GlobalTakePictureMenuFrame.OnTakedPicture := DoAddPictureFromMenu;
GlobalTakePictureMenuFrame.ShowMenu;
end
else
TDialogService.ShowMessage('Kamera kullanım izinleri verilmediği için işleminiz gerçekleştirilemiyor!');
end;
procedure TForm1.FotografAlindi(Sender: TObject; ABitmap: TBitmap);
begin
Self.imgDelphiCan.Prop.Picture.Assign(ABitmap);
end;
Proje ayarlarında yapılacak konfigürasyonlar aşağıdadır. [attachment=901] [attachment=900] TFrameTakePictureMenu Frame'inde yapılan değişiklikler aşağıdadır. [attachment=902] [attachment=903] [attachment=904] OrangeUI TakeFromPicture hataları - 41linea41 - 29-12-2019 Fesh Hocam ne yaptınız böyle 5-6 saatlik dersi tek bir mesaja sığdırmışsınız...Üstelik videoda çekip youtube yüklemişsiniz. Ne diyeceğimi bilemedim. Allah gönlünüze göre versin. Cvp: OrangeUI TakeFromPicture hataları - Fesih ARSLAN - 29-12-2019 (29-12-2019, Saat: 00:10)41linea41 Adlı Kullanıcıdan Alıntı: Fesh Hocam ne yaptınız böyle 5-6 saatlik dersi tek bir mesaja sığdırmışsınız...Üstelik videoda çekip youtube yüklemişsiniz. Hayrını görün. Ben alacağımı aldım ("Allah gönlünüze göre versin." ). OrangeUI TakeFromPicture hataları - Bay_Y - 24-01-2020 Teşekkürler Fesih bey elinize sağlık. |