Delphi Can
Proje Versiyon Bilgisi - Baskı Önizleme

+- Delphi Can (https://www.delphican.com)
+-- Forum: Delphi (https://www.delphican.com/forumdisplay.php?fid=3)
+--- Forum: Genel Programlama (https://www.delphican.com/forumdisplay.php?fid=6)
+--- Konu Başlığı: Proje Versiyon Bilgisi (/showthread.php?tid=7109)



Proje Versiyon Bilgisi - cvheneburi - 21-12-2022

Merhabalar, Hazırladığım projenin versiyon bilgisini otomatik olarak forma yazdırmak istiyorum naıl bir yol izlemeliyim.....


Cvp: Proje Versiyon Bilgisi - elixir84 - 21-12-2022

unit AppVersion;

{$IFDEF MACOS}
 {$DEFINE APPLE}
{$ENDIF}

{$IFDEF IOS}
 {$DEFINE APPLE}
{$ENDIF}


interface

 function GetApplicationVersion: string;

implementation

{$IFDEF ANDROID}
uses
 FMX.Helpers.Android, FMX.Platform.Android,
 Androidapi.JNI.JavaTypes, Androidapi.Helpers,
 Androidapi.JNI.GraphicsContentViewText,System.SysUtils;
{$ENDIF}
{$IFDEF APPLE}
uses
 {$IFDEF IOS}
 iOSapi.Foundation,
 {$ELSE}
 Macapi.Foundation,
 {$ENDIF}
 Macapi.Helpers,
 Macapi.ObjectiveC,System.SysUtils;
{$ENDIF}
{$IFDEF MSWINDOWS}
uses
 System.Types, System.SysUtils, Windows;
{$ENDIF}


function GetApplicationVersion: string;
{$IFDEF ANDROID}
var
 PackageManager: JPackageManager;
 PackageInfo: JPackageInfo;
begin
 Result := '?';
 try
   PackageManager := TAndroidHelper.Context.getPackageManager; //SharedActivityContext.getPackageManager;
   PackageInfo := PackageManager.getPackageInfo(TAndroidHelper.Context.getPackageName, 0);  //SharedActivityContext.getPackageName, 0);
   Result := JStringToString(PackageInfo.versionName)+'.'+inttostr(PackageInfo.versionCode);
 except
 end;
end;
{$ENDIF}
{$IFDEF IOS}
var
 AppKey: Pointer;
 AppBundle: NSBundle;
 BuildStr : NSString;
begin
 Result := '?';
 try
   AppKey := (StrToNSStr('CFBundleVersion') as ILocalObject).GetObjectID;

   AppBundle := TNSBundle.Wrap(TNSBundle.OCClass.mainBundle);
   BuildStr := TNSString.Wrap(AppBundle.infoDictionary.objectForKey(AppKey));
   Result := UTF8ToString(BuildStr.UTF8String);

 except
 end;
end;
{$ENDIF}
{$IFDEF MSWINDOWS}
var
 sExe: string;
 Size, Handle: DWORD;
 Buffer: TBytes;
 FixedPtr: PVSFixedFileInfo;
begin
 Result := '?';
 try
   sExe := ParamStr(0);
   Size := GetFileVersionInfoSize(PChar(sExe), Handle);
   if (Size = 0) then
     exit; // RaiseLastOSError;
   SetLength(Buffer, Size);
   if not GetFileVersionInfo(PChar(sExe), Handle, Size, Buffer) then
     exit; // RaiseLastOSError;
   if not VerQueryValue(Buffer, '\', Pointer(FixedPtr), Size) then
     exit; // RaiseLastOSError;
   Result := Format('%d.%d.%d.%d',
     [LongRec(FixedPtr.dwFileVersionMS).Hi,  //major
       LongRec(FixedPtr.dwFileVersionMS).Lo,  //minor
       LongRec(FixedPtr.dwFileVersionLS).Hi,  //release
       LongRec(FixedPtr.dwFileVersionLS).Lo]) //build

 except

 end;
end;
{$ENDIF}
{$IFDEF OSX}
var
 AppKey: Pointer;
 AppBundle: NSBundle;
 BuildStr : NSString;
begin
 Result := '?';
 try
   AppKey := (StrToNSStr('CFBundleVersion') as ILocalObject).GetObjectID;

   AppBundle := TNSBundle.Wrap(TNSBundle.OCClass.mainBundle);
   BuildStr := TNSString.Wrap(AppBundle.infoDictionary.objectForKey(AppKey));
   Result := UTF8ToString(BuildStr.UTF8String);

 except
 end;
end;
{$ENDIF}

end.


Kullanım

label1.Caption:='Versiyon : '+ AppVersion.GetApplicationVersion;



Proje Versiyon Bilgisi - ozcanm - 21-12-2022

Uses  Winapi.Windows;


function GetFileVersion1(exeName : string): string;
const
 c_StringInfo = 'StringFileInfo\040904E4\FileVersion';
var
 n, Len : cardinal;
 Buf, Value : PChar;
begin
 Result := '';
 n := GetFileVersionInfoSize(PChar(exeName),n);
 if n > 0 then begin
   Buf := AllocMem(n);
   try
     GetFileVersionInfo(PChar(exeName),0,n,Buf);
     if VerQueryValue(Buf,PChar(c_StringInfo),Pointer(Value),Len) then begin
       Result := Trim(Value);
     end;
   finally
     FreeMem(Buf,n);
   end;
 end;
end;

Kullanım;

Caption:=GetFileVersion1(ParamStr(0));



Proje Versiyon Bilgisi - cvheneburi - 23-12-2022

cevaplarınız için teşekkürler ancak her iki kodu kullandığımda değer boş geliyor, delphi 10.1 sürümünü kullanıyorum. herhangi bir ayar yapmak gerekiyormu tekrardan sistem üzerinden


Cvp: Proje Versiyon Bilgisi - cinarbil - 23-12-2022

Hayırlı sabahlar
Project / Options / Versiyon info dan  
versiyon bilgisini girdiğini varsayarak

 Ben bir procedure tanımladım.


procedure prgversiyon(const AppName: string; var V1, V2, V3, V4: Word);
var
 VerInfoSize, VerValueSize, Dummy: DWORD;
 VerInfo: Pointer;
 VerValue: PVSFixedFileInfo;
begin
 VerInfoSize := GetFileVersionInfoSize(PChar(AppName), Dummy);
 GetMem(VerInfo, VerInfoSize);
 GetFileVersionInfo(PChar(AppName), 0, VerInfoSize, VerInfo);
 VerQueryValue(VerInfo, '', Pointer(VerValue), VerValueSize);

 with VerValue^ do
 begin
   V1 := dwFileVersionMS shr 16;
   V2 := dwFileVersionMS and $FFFF;
   V3 := dwFileVersionLS shr 16;
   V4 := dwFileVersionLS and $FFFF;
 end;
   FreeMem(VerInfo, VerInfoSize);
end;

Kullanımı
procedure Tgiris_frm.FormCreate(Sender: TObject);
var
   V1, V2, V3, V4: word;
Begin
prgversiyon (Application.ExeName, V1, V2, V3,V4);
edt_Versiyon.Text:= Format('%d.%d.%d.%d', [V1, V2, V3,V4]);

Test edilmiştir.


Cvp: Proje Versiyon Bilgisi - cvheneburi - 23-12-2022

(23-12-2022, Saat: 09:08)cinarbil Adlı Kullanıcıdan Alıntı: Hayırlı sabahlar
Project / Options / Versiyon info dan  
versiyon bilgisini girdiğini varsayarak

 Ben bir procedure tanımladım.


procedure prgversiyon(const AppName: string; var V1, V2, V3, V4: Word);
var
 VerInfoSize, VerValueSize, Dummy: DWORD;
 VerInfo: Pointer;
 VerValue: PVSFixedFileInfo;
begin
 VerInfoSize := GetFileVersionInfoSize(PChar(AppName), Dummy);
 GetMem(VerInfo, VerInfoSize);
 GetFileVersionInfo(PChar(AppName), 0, VerInfoSize, VerInfo);
 VerQueryValue(VerInfo, '', Pointer(VerValue), VerValueSize);

 with VerValue^ do
 begin
   V1 := dwFileVersionMS shr 16;
   V2 := dwFileVersionMS and $FFFF;
   V3 := dwFileVersionLS shr 16;
   V4 := dwFileVersionLS and $FFFF;
 end;
   FreeMem(VerInfo, VerInfoSize);
end;

Kullanımı
procedure Tgiris_frm.FormCreate(Sender: TObject);
var
   V1, V2, V3, V4: word;
Begin
prgversiyon (Application.ExeName, V1, V2, V3,V4);
edt_Versiyon.Text:= Format('%d.%d.%d.%d', [V1, V2, V3,V4]);

Test edilmiştir.

Bu hatayı veriyor


Cvp: Proje Versiyon Bilgisi - cinarbil - 23-12-2022

(23-12-2022, Saat: 13:28)cvheneburi Adlı Kullanıcıdan Alıntı:
(23-12-2022, Saat: 09:08)cinarbil Adlı Kullanıcıdan Alıntı: Hayırlı sabahlar
Project / Options / Versiyon info dan  
versiyon bilgisini girdiğini varsayarak

 Ben bir procedure tanımladım.


procedure prgversiyon(const AppName: string; var V1, V2, V3, V4: Word);
var
 VerInfoSize, VerValueSize, Dummy: DWORD;
 VerInfo: Pointer;
 VerValue: PVSFixedFileInfo;
begin
 VerInfoSize := GetFileVersionInfoSize(PChar(AppName), Dummy);
 GetMem(VerInfo, VerInfoSize);
 GetFileVersionInfo(PChar(AppName), 0, VerInfoSize, VerInfo);
 VerQueryValue(VerInfo, '', Pointer(VerValue), VerValueSize);

 with VerValue^ do
 begin
   V1 := dwFileVersionMS shr 16;
   V2 := dwFileVersionMS and $FFFF;
   V3 := dwFileVersionLS shr 16;
   V4 := dwFileVersionLS and $FFFF;
 end;
   FreeMem(VerInfo, VerInfoSize);
end;

Kullanımı
procedure Tgiris_frm.FormCreate(Sender: TObject);
var
   V1, V2, V3, V4: word;
Begin
prgversiyon (Application.ExeName, V1, V2, V3,V4);
edt_Versiyon.Text:= Format('%d.%d.%d.%d', [V1, V2, V3,V4]);

Test edilmiştir.

Bu hatayı veriyor

verdiğim procedure ve komutlardan  bu hatayı vermez.  boş bir proje açın ve orada deneyin lütfen


Cvp: Proje Versiyon Bilgisi - cvheneburi - 25-12-2022

(23-12-2022, Saat: 13:51)cinarbil Adlı Kullanıcıdan Alıntı:
(23-12-2022, Saat: 13:28)cvheneburi Adlı Kullanıcıdan Alıntı: Bu hatayı veriyor

verdiğim procedure ve komutlardan  bu hatayı vermez.  boş bir proje açın ve orada deneyin lütfen

evet haklısınız boş projede çalışıyor. peki benim mevcut projemde neden çalışmaz hata neden kaynaklanır.


Cvp: Proje Versiyon Bilgisi - cinarbil - 25-12-2022

(25-12-2022, Saat: 00:09)cvheneburi Adlı Kullanıcıdan Alıntı:
(23-12-2022, Saat: 13:51)cinarbil Adlı Kullanıcıdan Alıntı: verdiğim procedure ve komutlardan  bu hatayı vermez.  boş bir proje açın ve orada deneyin lütfen

evet haklısınız boş projede çalışıyor. peki benim mevcut projemde neden çalışmaz hata neden kaynaklanır.

iyi günler derleme seçenekleri çok iyi ama öğrenmek zaman alabilir.
Debug modunda derleyerek  programı adım adım izleyeyebilirsiniz 
sizi için daha kolayı programda  otomatik üretilen formdan başlayarak 
adım adım 
showmessage ('burası aaa');

kullanarak  hatanın yerini yakalamalısınız.

Not : project / options / forms larda solda bulunan formu program içinde bir yerde oluşturuyorsanız kontrol edin.


Proje Versiyon Bilgisi - Frrst - 25-12-2022

Eğer sadece major ve minor versiyon yeterli olacaksa şu şekilde kullanabilirsiniz.

function PrgVersionStr: string;
var
 Rec: LongRec;
begin
 Rec := LongRec(GetFileVersion(ParamStr(0)));
 Result := Format('%d.%d', [Rec.Hi, Rec.Lo])
end;

Kullanımı
Label1.Caption := PrgVersionStr;