Delphi Can
With İfadesi ve Bir Kaç Kullanım Örneği - Baskı Önizleme

+- Delphi Can (https://www.delphican.com)
+-- Forum: Delphi (https://www.delphican.com/forumdisplay.php?fid=3)
+--- Forum: İpuçları (https://www.delphican.com/forumdisplay.php?fid=24)
+--- Konu Başlığı: With İfadesi ve Bir Kaç Kullanım Örneği (/showthread.php?tid=7735)

Sayfalar: 1 2


With İfadesi ve Bir Kaç Kullanım Örneği - RAD Coder - 20-05-2024

Delphi / Object Pascal'da With ifadesi sık kullanılmasa da yada pek tercih edilmese de, bazen de kaçınılmaz oluyor.
Neden, diye soracak olursanız...
Başvurulan her obje özelliğine ulaşmak için önüne karmaşık değişken adının eklenmesi ihtiyacını ortadan kaldırarak, kodu daha basitleştirir, sade ve daha okunaklı hale getirir. 
İç içe geçmiş karmaşık bileşen hiyerarşisindeki en uç özelliğe, tek bir ifade ile ulaşmanızı sağlar.

Aşağıda aktif kullanılan bir kaç uygulamadan aldığım örnek with ifadeleri yer almaktadır.
Not: 1 ve 2 ile işaretlenmiş resimler With ifadesi kullanılan ve With ifadesi olmadan kodun nasıl göründüğüne dair örneklerdir. 
Özellikle 3. örnek (1 ve 2 ile işaretli son resim) with'in amacını daha bariz gösteriyor. 

[attachment=2698]

[attachment=2699]

[attachment=2700]

[attachment=2701]

[attachment=2702]


With hakkında daha detaylı bilgi için: With Statements


With İfadesi ve Bir Kaç Kullanım Örneği - Bahadir.Alkac - 20-05-2024

Merhaba,

With deyimini mümkün olduğunca kullanmayın! Çok hızlı problemleri yazayım, siz karar verin.

1. Debug etmek çok zahmetli
With kullandığınız zaman değişkenin üzerine geldiğinizde maalesef debugger onu anlamıyor. Sizin, kodu yazarken üşendiğiniz ve with kullandığınız kısmı yazmanız gerekiyor. Üstelik bunu hint ekranında değil, Ctrl+F7 ile açtığınız debugger kısmına yazmanız gerekiyor. Yani aslında 3 kere debugger'dan değere bakacak olursanız neredeyse aynı eforu sarf etmiş oluyorsunuz.

2. Nested With
Bu en korkuncu! İç içe with kullanıldığında zaten her şey çorbaya dönüyor. 

3. Çarpışan propertyler
Form.Caption ve Label.Caption var. İkisi de caption. İşte with ifadesini kullandığınız nesnenin Caption ifadesi Text olarak değişirse (Firemonkey geçişinde Label.Caption -> Label.Text oldu) sizin kodunuz derlenir ama hiç de istediğiniz gibi çalışmaz.

4. Çarpışan methodlar
Property'lerdeki durumun bir benzeri methodlar için de geçerli.

5. Pratikte sadece 2-3 karakterden kurtuluyoruz. With ve With olmayan koda örnek:
with MMBelge.Items[0].Mustahsil.AliciBilgileri do
begin
 KisiAdi := 'Mehmet';
 Tckn := '123123123';
end;

// Bunun yerine
var AB := MMBelge.Items[0].Mustahsil.AliciBilgileri;
AB.KisiAdi := 'Mehmet';
AB.Tckn := '123123123';

Üstelik ikincisinde kod tamamlayıcı daha düzgün ve hızlı çalışyor.

Aslında 5. madde with ifadesinin asıl amacına bir ipucu olabilir. With ifadesinin derleyici tarafında nasıl çalıştığını biliyorsanız, kimi durumlarda daha performanslı kod ürettiğini de tahmin edebilirsiniz. Elbette günümüz bilgisayarlarında ciddiye alınacak bir fark değil. 

Sonuç olarak gerçekten de faydadan çok zararı var. Daha fazla yorum okumak istiyorsanız StackOverFlow'daki ilgili konulara bakabilirsiniz.  

Son olarak with deyiminden bağımsız, aşağıdaki gibi de kod yazmamanızı tavsiye ederim (burada with yerine for/while/if vs ne isterseniz yazabilirsiniz):
with TXyzObject.Create do
 try
    DoSometing
 finally
   Free;
 end;

Buradaki dert de with deyiminden sonra begin/end yerine try/finally bloğuna güvenerek kod yazmak. Bence bunun yerine şöyle yazın:
with TXyzObject.Create do
begin 
  try
    DoSometing;
  finally
    Free;
 end;
end;

Niye boş yere begin/end yazıyorum diyebilirsiniz. Kendiniz için değil, sizden sonra gelen programcının anlık bir hatasını engellemek için yazıyorsunuz. Oraya müdahale edecek başka bir programcı, hele de formatting bozuksa, yüksek olasılıkla hataya düşüyor. 

İyi çalışmalar


With İfadesi ve Bir Kaç Kullanım Örneği - sabanakman - 24-07-2024

İç içe arap saçı pardon with  Tongue 
with vBİIdİrİmRefKunye.DataControIIer, DataSet do



With İfadesi ve Bir Kaç Kullanım Örneği - bakyuz - 11-05-2025

With kullanımının bazı durumlarda performansa ciddi anlamda olumlu etkisi olmaktadır.

Sonuçlarım;

Delphi 12.3 - Release - x64
Kod:
With kullanarak süre: 15622 ms
With kullanmadan süre: 33578 ms


Delphi 12.3 - Release - x86
Kod:
With kullanarak süre: 11381 ms
With kullanmadan süre: 27332 ms


Örnek Benchmark;

Kod:
uses
 System.SysUtils, System.Diagnostics, System.Generics.Collections;

type
 TMyObject = class
 public
   Property1: Integer;
   Property2: Integer;
   Property3: Integer;
   procedure DoSomething;
 end;

procedure TMyObject.DoSomething;
begin
 Property1 := Property1 + 1;
 Property2 := Property2 + 2;
 Property3 := Property3 + 3;
end;

procedure xBenchmark;
var
 MyObjects: TList<TMyObject>;
 Stopwatch: TStopwatch;
 i, j: Integer;
begin
 MyObjects := TList<TMyObject>.Create;
 try
   for i := 1 to 10000000 do
     MyObjects.Add(TMyObject.Create);

   Stopwatch := TStopwatch.StartNew;
   for i := 0 to MyObjects.Count - 1 do
   begin
     with MyObjects[i] do
     begin
       for j := 1 to 1000 do
       begin
         Property1 := j;
         Property2 := j * 2;
         Property3 := j * 3;
         DoSomething;
       end;
     end;
   end;
   Stopwatch.Stop;
   Writeln('With kullanarak süre: ', Stopwatch.ElapsedMilliseconds, ' ms');

   Stopwatch := TStopwatch.StartNew;
   for i := 0 to MyObjects.Count - 1 do
   begin
     for j := 1 to 1000 do
     begin
       MyObjects[i].Property1 := j;
       MyObjects[i].Property2 := j * 2;
       MyObjects[i].Property3 := j * 3;
       MyObjects[i].DoSomething;
     end;
   end;
   Stopwatch.Stop;
   Writeln('With kullanmadan süre: ', Stopwatch.ElapsedMilliseconds, ' ms');
 finally
   for i := 0 to MyObjects.Count - 1 do
     MyObjects[i].Free;
   MyObjects.Free;
 end;
end;

begin
 xBenchmark;
 Readln;
end.



Cvp: With İfadesi ve Bir Kaç Kullanım Örneği - Bahadir.Alkac - 12-05-2025

(11-05-2025, Saat: 23:51)bakyuz Adlı Kullanıcıdan Alıntı: With kullanımının bazı durumlarda performansa ciddi anlamda olumlu etkisi olmaktadır.

Sonuçlarım;

Delphi 12.3 - Release - x64
Kod:
With kullanarak süre: 15622 ms
With kullanmadan süre: 33578 ms


Delphi 12.3 - Release - x86
Kod:
With kullanarak süre: 11381 ms
With kullanmadan süre: 27332 ms


Örnek Benchmark;

Kod:
uses
 System.SysUtils, System.Diagnostics, System.Generics.Collections;

type
 TMyObject = class
 public
   Property1: Integer;
   Property2: Integer;
   Property3: Integer;
   procedure DoSomething;
 end;

procedure TMyObject.DoSomething;
begin
 Property1 := Property1 + 1;
 Property2 := Property2 + 2;
 Property3 := Property3 + 3;
end;

procedure xBenchmark;
var
 MyObjects: TList<TMyObject>;
 Stopwatch: TStopwatch;
 i, j: Integer;
begin
 MyObjects := TList<TMyObject>.Create;
 try
   for i := 1 to 10000000 do
     MyObjects.Add(TMyObject.Create);

   Stopwatch := TStopwatch.StartNew;
   for i := 0 to MyObjects.Count - 1 do
   begin
     with MyObjects[i] do
     begin
       for j := 1 to 1000 do
       begin
         Property1 := j;
         Property2 := j * 2;
         Property3 := j * 3;
         DoSomething;
       end;
     end;
   end;
   Stopwatch.Stop;
   Writeln('With kullanarak süre: ', Stopwatch.ElapsedMilliseconds, ' ms');

   Stopwatch := TStopwatch.StartNew;
   for i := 0 to MyObjects.Count - 1 do
   begin
     for j := 1 to 1000 do
     begin
       MyObjects[i].Property1 := j;
       MyObjects[i].Property2 := j * 2;
       MyObjects[i].Property3 := j * 3;
       MyObjects[i].DoSomething;
     end;
   end;
   Stopwatch.Stop;
   Writeln('With kullanmadan süre: ', Stopwatch.ElapsedMilliseconds, ' ms');
 finally
   for i := 0 to MyObjects.Count - 1 do
     MyObjects[i].Free;
   MyObjects.Free;
 end;
end;

begin
 xBenchmark;
 Readln;
end.

Merhaba,

Aradaki fark olmasını bekliyordum, ama bu kadarını beklemiyordum. Ama kodu biraz inceleyip değiştirince tam tersi bir sonuç elde ettim (Ölçümleri Release modda derleyerek yaptım).

With kullanmadan süre: 7300 ms

With kullanarak süre: 9085 ms

Öncelikle with ve with olmayan ifadeler aynı şekilde çalışmıyor. İç içe iki loop kullanıyorsunuz, ama with kullanılmayan kod aşadaki gibi olursa with ile aynı şekilde çalışmasını bekleriz:

   Stopwatch := TStopwatch.StartNew;
  for i := 0 to MyObjects.Count - 1 do
  begin
   M := MyObjects[i];
    for j := 1 to 1000 do
    begin
      M.Property1 := j;
      M.Property2 := j * 2;
      M.Property3 := j * 3;
      M.DoSomething;
    end;
  end;
  Stopwatch.Stop;
  Writeln('With kullanmadan süre: ', Stopwatch.ElapsedMilliseconds, ' ms');
Yani J döngüsü başlamadan önce MyObjects[i]'yi bir değişkene almanız gerekiyor. Yoksa J döngüsü içinde sürekli liste elemanın erişim süresi eklemiş oluyorsunuz. Bunun with ifadesinin performansa etkisi ile bir ilişkisi yok. Bu değişikliği yapınca aradaki fark çok azalıyor.

Sonra ilginç bir şey daha fark ettim. Önce with olmayan döngüyü kullanırsam daha hızlı çalışıyor. Yani burada Delphi derleyicisinin ürettiği koddaki optimizasyon devreye giriyor sanırım. Sonra hiç üşenmedim ve with ile with olmayan ifadeleri iki ayrı method olarak yazdım. O zaman tutarlı bir şekilde with ifadesi biraz daha hızlı çalıştı. Sonra iki kodu sırayla test ettim. Bu sefer yine aynı süreleri elde ettim. Yani Delphi derleyicisinin optimizasyonu işleri fena karıştırıyor. 

Sonuç olarak hala aynı noktadayım. Ölçemeyeceğiniz kadar düşük bir performans artışı için işleri karıştıran, okumayı ve debug etmeyi zorlaştıran, hatalı kod yazdırma potansiyeli olan ve pratikte hiçbir faydası olmayan with ifadesinden uzak durmanızı tavsiye ederim. 

İyi çalışmalar


With İfadesi ve Bir Kaç Kullanım Örneği - atakansarr - 13-05-2025

hayırdır hocam panelmi yapıyorsunuz arkadaşlar dikkatli olalım bu arada şuan piyasa bir kaç kişi programlama öğrenip panel yapmaya çalışıyorlar


Cvp: With İfadesi ve Bir Kaç Kullanım Örneği - RAD Coder - 14-05-2025

(13-05-2025, Saat: 23:33)atakansarr Adlı Kullanıcıdan Alıntı: hayırdır hocam panelmi yapıyorsunuz arkadaşlar dikkatli olalım bu arada şuan piyasa bir kaç kişi programlama öğrenip panel yapmaya çalışıyorlar

Sick

Ne alaka. Forum yol geçen hanına döndü.
Bu başlıkta bunu yazmak hiç hoşuma gitmedi, kusura bakmayın.
Bir kaç güne bu mesajları temizleriz.


With İfadesi ve Bir Kaç Kullanım Örneği - berk06 - 14-05-2025

Whats-App-Image-2025-05-14-at-10-12-50.jpg


With İfadesi ve Bir Kaç Kullanım Örneği - mrmarman - 14-05-2025

Benim tercihim olarak "With" kullanımının en verimli hali JSON Object dallanmasında JSONObject mi JSONValue mi JSONArray mi olduğu ana daldan alt dallara doğru değişken olduğundan....

LJSONValue := PARSEişlemi....
try

finally
  FreeAndNil(LJSONValue);
end;

içerisindeki dalları Width ile kullanmayı tercih ediyorum, çünkü her width açılımı farklı bir JSON titpine işaret edebiliyor.. 

Hem de zaman zaman aynı diziye TJSONObject pair  veya TJSONArray item muamelesi de çekmek gerekebiliyor. Çünkü API'lerden iç içe dallanan dinamik bir yazpı gelebiliyor. Ne geldiğini gelince veri tipine göre anlayabiliyoruz.

JSON işlemlerinde bir de Create / Free / Remove işlerine gerek kalmayacak şekilde ana nesne üzerinde gezinmiş oluyoruz. Alt nesne create / parse vs işine girmeden temiz çıkıyoruz.

örneğin
   with TJSONObject( LSJON.FindValue('result') ) do begin
     with TJSONArray( FindValue('MainArray') do 
     begin
        for i : 0 to count-1 do
        begin
          with TJSONObject( item[i] ) do // her item'i TJSONObject olarak aldık.
          begin
            with TJSONArray( findvalue('SubArray') ) do 
            begin

            end;
          end;
        end;
     end; 
   end;

bu şekilde kafa karışıklığı olmuyor. Diğer türlü her bir dallanma için bir değişken atamak veya kendisini başa yazınca satır uzaması oluyor ki JSON API işlemlerinde bir süre sonra copy/paste sonucu DEBUG işlemini zorlaştırmaya kadar gidiyor. Bu şekilde INDENT (soldan TAB ile içeri doğru derinlik sayısı ) özen gösterdiğim sürece hızla sonuca ulaşabiliyorum


With İfadesi ve Bir Kaç Kullanım Örneği - Hayati - 14-05-2025

Konuya yabancıyım ama ilgimi çekti, ai lerle biraz tartıştıktan sonra, son tahlilde @mrmarman Muharrem abinin yaklaşımı desteklenirken, tek geliştiricili ve/veya kısa vadeli projeler değilse

1.
var
  LValue, LMainArrayItem, LSubArrayItem: TJSONValue;
  LResultObj, LItemObj: TJSONObject;
  LMainArray, LSubArray: TJSONArray;
  I, J: Integer;
begin
  try
    LValue := LJSONValue.FindValue('result');
    if not (LValue is TJSONObject) then
      raise Exception.Create('Geçersiz "result" nesnesi');

    LResultObj := TJSONObject(LValue);

    LMainArray := LResultObj.Values['MainArray'] as TJSONArray;
    if not Assigned(LMainArray) then
      raise Exception.Create('"MainArray" dizisi bulunamadı');

    for I := 0 to LMainArray.Count - 1 do
    begin
      LMainArrayItem := LMainArray.Items[I];
      if not (LMainArrayItem is TJSONObject) then
        raise Exception.Create(Format('MainArray[%d] bir JSON nesnesi değil', [I]));

      LItemObj := TJSONObject(LMainArrayItem);

      LSubArray := LItemObj.Values['SubArray'] as TJSONArray;
      if not Assigned(LSubArray) then
        Continue; // Alt dizi yoksa atla

      for J := 0 to LSubArray.Count - 1 do
      begin
        LSubArrayItem := LSubArray.Items[J];
        // LSubArrayItem üzerinde işlem yapılabilir
      end;
    end;

  except
    on E: Exception do
    begin
      // Hata loglanabilir, kullanıcıya gösterilebilir vs.
      ShowMessage('JSON işlemi sırasında hata: ' + E.Message);
    end;
  end;
end;

2
uses
 System.SysUtils, System.JSON, Vcl.Dialogs;

function TryGetJSONObject(const AValue: TJSONValue; out AObject: TJSONObject): Boolean;
begin
 Result := AValue is TJSONObject;
 if Result then
   AObject := TJSONObject(AValue)
 else
   AObject := nil;
end;

function TryGetJSONArray(const AValue: TJSONValue; out AArray: TJSONArray): Boolean;
begin
 Result := AValue is TJSONArray;
 if Result then
   AArray := TJSONArray(AValue)
 else
   AArray := nil;
end;

procedure ParseJSONResponse(const LJSONValue: TJSONValue);
var
 LResultObj, LItemObj: TJSONObject;
 LMainArray, LSubArray: TJSONArray;
 LMainArrayItem, LSubArrayItem: TJSONValue;
 I, J: Integer;
begin
 try
   if not TryGetJSONObject(LJSONValue.FindValue('result'), LResultObj) then
     raise Exception.Create('Geçersiz veya eksik "result" nesnesi');

   if not TryGetJSONArray(LResultObj.Values['MainArray'], LMainArray) then
     raise Exception.Create('"MainArray" dizisi bulunamadı veya geçersiz');

   for I := 0 to LMainArray.Count - 1 do
   begin
     LMainArrayItem := LMainArray.Items[I];
     if not TryGetJSONObject(LMainArrayItem, LItemObj) then
     begin
       // Dizi içinde geçersiz bir öğe varsa, atla ama loglayabilirsin
       Continue;
     end;

     if not TryGetJSONArray(LItemObj.Values['SubArray'], LSubArray) then
       Continue;

     for J := 0 to LSubArray.Count - 1 do
     begin
       LSubArrayItem := LSubArray.Items[J];
       // SubArray içindeki her öğe burada işlenebilir
       // Örnek: ShowMessage(LSubArrayItem.ToString);
     end;
   end;

 except
   on E: Exception do
   begin
     // Uygulama çökmesin, loglama veya kullanıcıya bilgi verme için kullanılabilir
     ShowMessage('JSON işlemi sırasında hata oluştu: ' + E.Message);
   end;
 end;
end;

Kullanımı

procedure TForm1.Button1Click(Sender: TObject);
var
 LJSONValue: TJSONValue;
begin
 LJSONValue := TJSONObject.ParseJSONValue(Memo1.Text);
 try
   if Assigned(LJSONValue) then
     ParseJSONResponse(LJSONValue)
   else
     ShowMessage('JSON parse edilemedi.');
 finally
   LJSONValue.Free;
 end;
end;

gibi yapılar daha uygun(muş). İstersem Class, Record kullanımlı örnekler de sunarmış Smile 
Benim anladığım, olay "haklı" "haksız" (dikkatinizi çekerim tırnak içinde) meselesinden çok projenin büyüklüğüne bağlı... Sonuçta 50 satırlık kodda proje, 50.000 satırlık kodda proje.