Delphi Can
Image Compare - Baskı Önizleme

+- Delphi Can (https://www.delphican.com)
+-- Forum: Delphi (https://www.delphican.com/forumdisplay.php?fid=3)
+--- Forum: Genel Programlama (https://www.delphican.com/forumdisplay.php?fid=6)
+--- Konu Başlığı: Image Compare (/showthread.php?tid=7778)



Image Compare - bydelphi - 29-06-2024

Merhabalar, 

Aldığım capture bitmapı bir önceki ile karşılaştırıp bu iki bitmap image aynı mı bunu kontrol etmek istiyorum,
iki bitmapin boyutunu byte cinsinden cardinal olarak baktım, 
Stream size kontrolü yaptım, stream base64e çevirip özet md5 karşılaştırması checksum yaptım,  
yada netten araştırdığım image comparsion fonksiyonları ile denedim , 
ama aynı anda aldığım iki capture arasında bile fark oluşuyor, 
bu işlemi Çok kaynak tüketmeden kontrol etmemin  sağlıklı bir yolu varmıdır.
 
        DSK := GetDC(GetDesktopWindow);
        BMP := TBitmap.Create;
        BMP.Width := Screen.Width;
        BMP.Height := Screen.Height;
        BitBlt(BMP.Canvas.Handle, 0, 0, BMP.Width, BMP.Height,DSK, 0, 0,SrcCopy);

 Not : bu konuyu, önceki sorumun devamı olarak onun altına eklemiştim, 
aslında faklı konu , şimdi burada yeni konu açmış oldum. 
umarım yanlış yapmamışımdır.  
https://www.delphican.com/showthread.php?tid=4620&pid=55526#pid55526
Teşekkürler.


Image Compare - mrmarman - 29-06-2024

Merhaba
ne tip bir görüntü farkı oluşuyor?
Bunu şöyle sorayım, ekranda sadece bir pixel rengi değişse değişim sayılır mı?

Bu değişim sadece ekran değişti tarzı true/false tek bir sonuç mu döndürecek? bu da önemli bir soru.

Hız kazanmak için resmi 1 bit siyah beyaz yapıp karşılaştırırsanız çok performans kazanırsınız.

ScanLine araştırın, 1 satırı size array olarak verir.
iki resmin aynı satırında dizi elemanı karşılaştırınca en az bir fark bulursanız döngüyü sonlandırıldıp değişti diyebilirsiniz.


Image Compare - bydelphi - 30-06-2024

evet aynen hocam true/false istiyorum, çok hassas pixel pixel kontol çok gerekli değil,
ekranda fare hareketi yok , taskbardaki sanye bile kapalı, yani ekran bekleme vaziyette herşey aynı iken,
timer ile 1 sn arayla aldığım iki screenshot capture bitmap aslında aynı ama bunu farkedemedim.

mesela cursorın konumu değiştiğinde evet faklı resim pixel değişti , ama hiç bir hareket yokken aldığım iki screenshot ın aynı olduğunu anlamak istiyorum.
aynı resim ise farklı bir süreç işleyecek benim için bunu ayırt etmeye çalışıyorum açıkçası, sadece true/false.
üstte de dediğim gibi iki bitmapin boyutunu byte cinsinden cardinal olarak baktım,
Stream size kontrolü yaptım, streamı base64e çevirip özet md5 karşılaştırması checksum yaptım,
yada netten araştırdığım image comparsion fonksiyonları ile denedim ,
ama 1 saniye arayla aldığım ve ekranda hiçbir değişiklik yokken mouse bile kıpırdamadan aldığım ekran resimlerini, farklı görüyor, aslında aynı olmalılar,
belkide telorans vermek mi gerekir bilemiyorum.

ScanLine için tüm satırları dizi olarak karşılaştırıp herhangi bir satırda ki farklılık kontrol edilebilr, deneyeceğim.
burada da örneğin 30 pixel lik bir tolerans verilebilir toplamda, tüm satırlarda bu farklı aşınca değişimden bahsedilebilir belki,
Desteğin için teşekkürler


Image Compare - mrmarman - 30-06-2024

Boştayken bir sınıf hazırladım. Denemek isterseniz diye...

ScreenRegion vermezseni fullscreen bakar. 
- FScreenAlert.Region (örnekteki gibi) vermişseniz o alana bakar olur. 
- Region sıfırlamak için FScreenAlert.ScreenAll komutu verirsiniz.
- ShowRegion (örnekteki gibi) TRUE ise mavi bir çerçeve içerisinde bakılan alanı gösterir
- Treshold değeri değişim sayısı miktarı rakamsal olarak ifade edilir, bu değer aşıldığında OnScreenAlert  eventi tetiklenir. orada dilediğinizi yaparsınız.
- Interval ise bildiğiniz Timer interval milisaniye cinsinden bakar. 500 demek saniyede iki defa (yarım saniye) manasında.

- State := TRUE ise timer başlar FALSE ise durur



Kullanımı :


uses ScreenAlertU;

var
  FScreenAlert : tScreenAlert;

procedure TForm1.BitBtn1Click(Sender: TObject);
begin
  if NOT Assigned(FScreenAlert) then
  begin
    FScreenAlert := tScreenAlert.Create;
    FScreenAlert.Interval       := 500;
    FScreenAlert.OnScreenAlert  := DoScreenAlert;
    FScreenAlert.ScreenRegion   := rect(400,400,800,600);
    FScreenAlert.ShowRegion     := true;
    FScreenAlert.Treshold       := 1;
  end;

  FScreenAlert.State := NOT FScreenAlert.State;
end;

procedure TForm1.DoScreenAlert(sender: TObject);
begin
  Memo1.Lines.Add( 'Change detected...: ' + DateTimeToStr(now) + ' - Fark: ' + IntToStr(FScreenAlert.DiffCount) );
end;

procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  if Assigned(FScreenAlert)
    then
      FreeAndNil(FScreenAlert);

end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  ReportMemoryLeaksOnShutdown := true;
end;



Unit :



unit ScreenAlertU;

interface

Uses
  WinApi.Windows,
  Vcl.Forms,
  Vcl.ExtCtrls, Vcl.Graphics, Vcl.Dialogs,
  System.SysUtils, System.Classes, System.Types;

type
  tScreenAlert = class( TObject )
  private
  var
    FTimer        : Vcl.ExtCtrls.TTimer;
    FBitmap1,
    FBitmap2      : TBitmap;
    FInterval     : Integer;
    FScreenAlert  : TNotifyEvent;
    FState        : boolean;
    FRect         : TRect;
    FDiffCount    : Integer;
    FTreshold     : Integer;
    FShowRegion   : boolean;

    procedure DoOnTimer(sender: TObject);
    procedure ScreenCap(var aBitmap: TBitmap; aRect: TRect);
    procedure SetInterval(value: Integer);
    procedure SetState(value: boolean);
    function  CompareBitmaps(aBitmap1, aBitmap2: TBitmap): Integer;
  public
    constructor Create;
    destructor  Destroy; override;
    property    Interval : Integer read FInterval write SetInterval;
    property    OnScreenAlert: TNotifyEvent read FScreenAlert write FScreenAlert;
    property    State : boolean read FState write SetState;
    property    ScreenRegion : TRect read FRect write FRect;
    property    DiffCount : Integer read FDiffCount;
    property    Treshold  : Integer read FTreshold write FTreshold;
    procedure   ScreenAll;
    property    ShowRegion : boolean read FShowRegion write FShowRegion;
  end;

implementation

{ tScreenAlert }

constructor tScreenAlert.Create;
begin
  inherited;

  FTreshold     := 100;
  FDiffCount    := 0;
  FShowRegion   := false;

  FRect   := Rect(0,0,0,0);
  FTimer  := TTimer.Create(nil);
  FTimer.Interval := 1000;
  FTimer.OnTimer  := DoOnTimer;
end;

destructor tScreenAlert.Destroy;
begin
  FTimer.Enabled := false;
  FreeAndNil(FTimer);

  FreeAndNil(FBitmap1);
  FreeAndNil(FBitmap2);

  inherited;
end;

procedure tScreenAlert.ScreenAll;
begin
  FRect := Rect(0,0,0,0);
end;

procedure tScreenAlert.ScreenCap(var aBitmap: TBitmap; aRect: TRect);
var
  LCanvas : TCanvas;
  LRectSource,
  LRectTarget : TRect;
begin
  if Assigned(aBitmap)
    then
      FreeAndNil(aBitmap);

  aBitmap := TBitmap.Create;
  LCanvas := TCanvas.Create;
  LCanvas.Handle := GetWindowDC(GetDesktopWindow);
  try
    if (aRect.Width > 0) or (aRect.Height > 0) then
    begin // screen region
      aBitmap.SetSize(aRect.Width, aRect.Height);
      LRectSource       := aRect;
      LRectTarget  := Rect(0,0,aRect.Width, aRect.Height);
    end
    else
    begin // full screen
      aBitmap.SetSize(Screen.DesktopRect.Width, Screen.DesktopRect.Height);
      LRectSource       := Screen.DesktopRect;
      LRectTarget  := Screen.DesktopRect;
    end;
    aBitmap.Canvas.CopyRect(LRectTarget, LCanvas, LRectSource);

    if FShowRegion then
    begin
      LCanvas.Pen.Color   :=  clblue;
      LCanvas.brush.Style :=  bsClear;
      LCanvas.Pen.Width   :=  1;
      LCanvas.Pen.Style   :=  TPenStyle.psDashDotDot;

      LRectSource.Left    := LRectSource.Left - LCanvas.Pen.Width;
      LRectSource.Top     := LRectSource.Top  - LCanvas.Pen.Width;
      LRectSource.Right   := LRectSource.Right   + 2*LCanvas.Pen.Width;
      LRectSource.Bottom  := LRectSource.Bottom  + 2*LCanvas.Pen.Width;

      LCanvas.Rectangle(LRectSource);
    end;

  finally
    ReleaseDC(0, LCanvas.Handle);
    LCanvas.Free;
  end;
end;

procedure tScreenAlert.SetInterval(value: Integer);
begin
  FInterval       := value;
  FTimer.Enabled  := false;
  FTimer.Interval := FInterval;
  FTimer.OnTimer  := DoOnTimer;
end;

procedure tScreenAlert.SetState(value: boolean);
begin
  FState := value;
  FTimer.Enabled := FState;
  if FState then DoOnTimer(self);

end;

procedure tScreenAlert.DoOnTimer(sender: TObject);
begin
  if NOT Assigned(FBitmap1)
  then
    ScreenCap(FBitmap1, FRect)
  else
  begin
    ScreenCap(FBitmap2, FRect);
    FDiffCount  := CompareBitmaps(FBitmap1, FBitmap2);

    if FDiffCount > FTreshold then
    begin
      FBitmap1.Assign(FBitmap2);
      FreeAndNil(FBitmap2);
      if Assigned(FScreenAlert)
        then FScreenAlert(self);
    end;
  end;
end;

function tScreenAlert.CompareBitmaps(aBitmap1, aBitmap2: TBitmap): Integer;
var
  i, j : Integer;

  pLine1 : PByteArray;
  pLine2 : PByteArray;

begin
  result := 0;

  aBitmap1.PixelFormat := pf8bit;
  aBitmap2.PixelFormat := pf8bit;

  for i := 0 to aBitmap1.Height-1 do
  begin
    pLine1 := aBitmap1.ScanLine[i];
    pLine2 := aBitmap2.ScanLine[i];
    for j := 0 to aBitmap1.Width-1 do
    begin
      if pLine1^[j] <> pLine2^[j]
        then
          inc(result); // Farkları sayıyoruz...
    end;
  end;

end;

end.




qbazvogvpugaw9sevl6z.gif


Image Compare - bydelphi - 01-07-2024

Tavsiyen üzere ScanLine ile testler, denemeler yaparken, sen işi bitirmişin.
Harikasın teşekkürler, eline sağlık,