(08-08-2025, Saat: 09:01)mrmarman Adlı Kullanıcıdan Alıntı: Güzel çalışma.

- Kodunuzu inceledim HTML parse temelli olmuş.
- Olumsuzluklar konusundaki soru işaretlerimi paylaşayım. Sonra da çözümü paylaşayım.

? Her gün verisi için 500 milisaniye (sleep) beklemeli ve birer gün arttırımlı yapılan çoklu sorgu, kaynak site tarafından saldırı olarak nitelendirilebilir.
? Sayfa tasarımındaki oynamalar projenizi / fonksiyonlarınızı çalışmaz hale getirebilir.

- Kaynak aldığınız sitenin verileri nasıl çektiğini incelediğimde aslında text bazlı cevap verdiğini de gördüm.

- Şu aşağıdaki link formatını denemek isteyebilirsiniz. 
- Aynı siteden bir kerede geriye dönük kaç günlük veri isterseniz o kadar veri çekebildiğinizi göreceksiniz. Böylece gün gün döngüden de ardışık sorgudan da kaçınmış olacaksınız.

Kod:

aşağıdaki şekilde örnekleyebiliriz....

https://altin.in/grafikur.asp?did=flash_grafik&ca=1&islem=gunluk&sa=sat&kur=GA&banka=altin&k=&gun=1
https://altin.in/grafikur.asp?did=flash_grafik&ca=1&islem=gunluk&sa=sat&kur=GA&banka=altin&k=&gun=10
https://altin.in/grafikur.asp?did=flash_grafik&ca=1&islem=gunluk&sa=sat&kur=GA&banka=altin&k=&gun=1000
https://altin.in/grafikur.asp?did=flash_grafik&ca=1&islem=gunluk&sa=sat&kur=GA&banka=altin&k=&gun=3000

gibi gun parametresi gelecek verinin gün sayısını girmenize müsaade ediyor.

sondaki gun = 1 olan kısmı gun=3000 derseniz 3000 günlük veriyi bir defada çekebilir hız ve performansı zirveye taşıyabilirsiniz.

Not: 7040'a kadar denedim 1 Mayıs 2006'ya kadar geriye uzandı.

Çalışmalarınızda başarılar.

uses  System.Net.HttpClientComponent,
      System.Net.HttpClient,
      System.JSON,
      System.Generics.Collections;

type
  tGoldInfo = record
    kur   : currency;
    date  : string;
  end;
  tGoldArray = array of tGoldInfo;

function FetchGoldExchange( aDay:Integer = 1 ): tGoldArray;
const
  LUrlFmt = 'https://altin.in/grafikur.asp?did=flash_grafik'
            + '&ca=1&islem=gunluk&sa=sat&kur=GA&banka=altin&k=&gun=%d';
var
  LResponse   : IHTTPResponse;
  LText       : String;
  LJSONObject : TJSONObject;
  LKurObject  : TJSONObject;
  LSatisArray : TJSONArray;
  LTarihArray : TJSONArray;
  i           : Integer;
begin
  finalize(result);
  with TNetHTTPClient.Create(nil) do
  try
    LResponse := Get( format(LUrlFmt, [aDay]) );
    if LResponse.StatusCode = 200 then
    begin
      LText := LResponse.ContentAsString;

      if ( pos('{kur:', LText) > 0 ) then
      begin
        System.Delete(LText, 1, pos('{kur:', LText)-1 );
        if pos( ';graf.yarat', LText ) > 0 then
        begin
          LText := Copy(LText, 1, pos(';graf.yarat', LText)-1 );

          // JSON Format düzeltme... (başlıklar çift tırnak içine alınmalı...)
          LText := StringReplace( LText, 'kur', '"kur"', [] );
          LText := StringReplace( LText, 'satis', '"satis"', [] );
          LText := StringReplace( LText, 'tarih', '"tarih"', [] );

          // JSON parse et

          LJSONObject := TJSONObject.ParseJSONValue(trim(LText)) as TJSONObject;
          if LJSONObject <> nil then
          try
            LKurObject   := LJSONObject.FindValue('kur') as TJSONObject;

            if LKurObject <> nil then
            begin

              LSatisArray  := LKurObject.FindValue('satis') as TJSONArray;
              LTarihArray  := LKurObject.FindValue('tarih') as TJSONArray;

              for i := 0 to LTarihArray.Count-1 do
              begin
                SetLength(result, length(result)+1);
                With Result[ high(result) ] do
                begin
                  kur   := TJSONNumber( LSatisArray.items[i] ).AsDouble;
                  date  := LTarihArray.items[i].Value;
                end;
              end;
            end;

          finally
            LJSONObject.Free;
          end;
        end
        else
          ShowMessage('Geçerli bir JSON bölümü bulunamadı.');
      end;
    end else
    begin
      MessageDlg('Failed...' + sLineBreak + LResponse.ContentAsString,
        TMsgDlgType.mtError, [mbAbort], 0 );
    end;

  finally
    free;
  end;
end;


// Örnek kullanım
procedure TForm1.BitBtn1Click(Sender: TObject);
var
  LResult : tGoldArray;
  i : Integer;
begin
  LResult := FetchGoldExchange( 7040 );

  // Memo'yu dolduralım...
  if Length(LResult) > 0 then
  begin
    Memo1.Lines.Clear;
    Memo1.Lines.BeginUpdate;
    for i := Low(LResult) to High(LResult)
      do
        Memo1.Lines.Add(
          format( '%20s  : %10s', [ LResult[i].date,
            format('%0.4f', [LResult[i].kur]) ]) );
    Memo1.Lines.EndUpdate;
  end;

  Finalize( LResult ); // Array boşalt..
end;

def fix_turkish_chars(text):
    replacements = {
       'ÄŸ': 'ğ',
       'Ä°': 'İ',
       'ı': 'ı',
       'ç': 'ç',
       'ö': 'ö',
       'ÅŸ': 'ş',
       'ü': 'ü',
       'Ç': 'Ç',
       'Ö': 'Ö',
       'Åž': 'Ş',
       'Ãœ': 'Ü'
   }
   for wrong, correct in replacements.items():
       text = text.replace(wrong, correct)
   return text

def extract_data(content, start_date='"02 Mayıs 2006"', end_date='"09 Ağustos 2025"'):    
   price_start = content.find('satis:[') + 7
    price_end = content.find(']', price_start)
   prices = [float(x.strip()) for x in content[price_start:price_end].split(',')]
      
   date_part = content[content.find(start_date):]
   dates = []
   current_pos = 0
   
   while True:
       quote1 = date_part.find('"', current_pos)
       if quote1 == -1:
           break
       quote2 = date_part.find('"', quote1 + 1)
       if quote2 == -1:
           break
       
       date_str = date_part[quote1 + 1:quote2]
       if not any(char.isdigit() for char in date_str):
           current_pos = quote2 + 1
           continue
     
       date_str = fix_turkish_chars(date_str)
       dates.append(date_str)
       current_pos = quote2 + 1
              
       if end_date.strip('"') in date_str:
           break
   
   return prices[:len(dates)], dates

def create_csv(prices, dates, filename):
    with open(filename, 'w', encoding='utf-8-sig') as f:  # UTF-8 BOM
       f.write("Tarih,Altın Fiyatı (TL)\n")
       for date, price in zip(dates, prices):
           f.write(f'"{date}",{price}\n')

def main():
   try:
       with open('data.txt', 'r', encoding='utf-8') as f:
           content = f.read()
       
      
       content = fix_turkish_chars(content)
    
   
       prices, dates = extract_data(content, 
                                  start_date='"02 Mayıs 2006"',
                                  end_date='"09 Ağustos 2025"')
       
       if len(prices) != len(dates):
           min_len = min(len(prices), len(dates))
           prices = prices[:min_len]
           dates = dates[:min_len]
           print(f"Uyarı: {len(prices)} fiyat, {len(dates)} tarih bulundu. İlk {min_len} kayıt kullanıldı.")
       
       create_csv(prices, dates, 'altin_fiyatlari.csv')
       print(f"Başarılı: {len(dates)} günlük kayıt oluşturuldu.")
   
   except FileNotFoundError:
       print("Hata: data.txt dosyası bulunamadı!")
   except Exception as e:
       print(f"Beklenmeyen hata: {str(e)}")

if __name__ == "__main__":
   main()