Telefondan Arama yapmak

[barissagir]

Merhabalar, 

Aşağıdaki kodla Android le arama yapabiliyorum. ama IOS kısmında hiçbişey olmuyor. 
Hatada olmuyor aramada yapmıyor.
Sizce nerde hata yapıyorum?

procedure TAnaF.TelefonlaAra(Telefonx: String);
var
FPhoneDialerService: IFMXPhoneDialerService;
FCallPhonePermission: string;

begin
 TPlatformServices.Current.SupportsPlatformService(IFMXPhoneDialerService, IInterface(FPhoneDialerService));


 {$IFDEF ANDROID}
 FCallPhonePermission := JStringToString(TJManifest_permission.JavaClass.CALL_PHONE);

   if Telefonx <> '' then
     PermissionsService.RequestPermissions([FCallPhonePermission], procedure(const APermissions: TClassicStringDynArray; const AGrantResults: TClassicPermissionStatusDynArray)
   begin
     if (Length(AGrantResults) = 1) and (AGrantResults[0] = TPermissionStatus.Granted) then

       FPhoneDialerService.Call(Telefonx)
     else
     begin
      TDialogService.ShowMessage('Telefon açma izniniz yok!');
     end;
   end);

  {$ENDIF}

  {$IFDEF IOS}

  if Assigned(FPhoneDialerService) then
    if Telefonx <> '' then
      begin

         FPhoneDialerService.Call(Telefonx);
      end;
  {$ENDIF}




end;

[bakyuz]

Cihazda mı test ediyorsunuz yoksa simulatörde mi? Arama işlemi cihazda çalışmaktadır. Simulatörde çalışmaz.

[emozgun]

Merhaba @barissagir
Apple Developer'da telefon aramaları API'sinin CallKit olduğu URL şeklinde çağırılacağı anlatılıyor: 
https://developer.apple.com/documentation/callkit/ 
https://developer.apple.com/forums/thread/748156

Kastri'de https://github.com/DelphiWorlds/Kastri/t.../Demos/SMS ios sms gönderme demosu ve CallKit kütüphanesi https://github.com/DelphiWorlds/Kastri/b...allKit.pas mevcut

Ayrıca Swift örneği mevcut: https://stevenpcurtis.medium.com/create-...c07fd0e03e
Buradaki swift kodları https://gemini.google.com ile Delphi'ye çevirmeyi deneyebilirsin

[barissagir]

(21-06-2025, Saat: 19:18)bakyuz Adlı Kullanıcıdan Alıntı: Cihazda mı test ediyorsunuz yoksa simulatörde mi? Arama işlemi cihazda çalışmaktadır. Simulatörde çalışmaz.

Cihazda test ediyorum.

[barissagir]

iOS 18'de Delphi'nin kullandığı openURL metodunun artık çalışmamasına neden olan bir değişiklik olmuş.
 
C:\Program Files (x86)\Embarcadero\Studio\23.0\source\FMX klasöründe  FMX.PhoneDialer.iOS.pas. 

Bu dosyayı proje klasörüne kopyalamalıyız. ve aşağıdaki kodlarla arama yapabiliyoruz.

unit Unit1;



interface



uses

 System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,

 FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics, FMX.Dialogs, FMX.StdCtrls,

 FMX.Controls.Presentation, FMX.Edit,  FMX.Platform,

 iOSapi.Foundation, iOSapi.UIKit, Macapi.Helpers, Macapi.ObjectiveC;



type

 TUIApplicationOpenURLCompletionProc = procedure(success: Boolean) of object;



 UIApplicationEx = interface(UIApplication)

   ['{C1BE9D49-21ED-4723-90F0-0199A54D16FE}']

   procedure openURL(url: NSURL; options: NSDictionary; completionHandler: TUIApplicationOpenURLCompletionProc); cdecl;

 end;



 TUIApplicationEx = class(TOCGenericImport<UIApplicationClass, UIApplicationEx>) end;



type

 TForm1 = class(TForm)

   Edit1: TEdit;

   Button1: TButton;

   procedure Button1Click(Sender: TObject);

 private

   { Private declarations }



 public

   { Public declarations }

 end;



var

 Form1: TForm1;



implementation



{$R *.fmx}



function SharedApplicationEx: UIApplicationEx;

begin

 Result := TUIApplicationEx.Wrap(TUIApplication.OCClass.sharedApplication);

end;



function Ara(const TelefonNumarasi: string): Boolean;

var

 URL: NSURL;

begin

 URL := StrToNSUrl(Format('tel:%s', [TelefonNumarasi]));

 Result := SharedApplicationEx.canOpenURL(URL);

 if Result then

   SharedApplicationEx.openURL(URL, nil, nil);

end;



procedure TForm1.Button1Click(Sender: TObject);

begin

Ara(edit1.Text);

end;


end.