Konuyu Oyla:
  • Derecelendirme: 5/5 - 1 oy
  • 1
  • 2
  • 3
  • 4
  • 5
VPN İstemcisi ve Delphide VPN
#11
Merhaba @mrmarman eğer sorun yoksa projeyi paylaşabilir misiniz?
Teşekkürler
Cevapla
#12
(09-12-2018, Saat: 21:48)mrmarman Adlı Kullanıcıdan Alıntı: Merhaba.

- Ben şöyle yapıyorum. Önce bir VPN bağlantı ayarı yapın. Sonra bunu PBK olarak çıktı alın.

Örnek :
[VPN_Book]
Encoding=1
PBVersion=4
Type=2
AutoLogon=0
UseRasCredentials=1
LowDateTime=1229306624
HighDateTime=30663231
DialParamsUID=326656921
Guid=EE5786CDCC9F034FB9C123BF9F657186
VpnStrategy=1
ExcludedProtocols=0
LcpExtensions=1
DataEncryption=8
SwCompression=0
NegotiateMultilinkAlways=0
SkipDoubleDialDialog=0
DialMode=0
OverridePref=15
RedialAttempts=3
RedialSeconds=60
IdleDisconnectSeconds=0
RedialOnLinkFailure=1
CallbackMode=0
CustomDialDll=
CustomDialFunc=
CustomRasDialDll=
ForceSecureCompartment=0
DisableIKENameEkuCheck=0
AuthenticateServer=0
ShareMsFilePrint=1
BindMsNetClient=1
SharedPhoneNumbers=0
GlobalDeviceSettings=0
PrerequisiteEntry=
PrerequisitePbk=
PreferredPort=VPN4-0
PreferredDevice=WAN Miniport (PPTP)
PreferredBps=0
PreferredHwFlow=1
PreferredProtocol=1
PreferredCompression=1
PreferredSpeaker=1
PreferredMdmProtocol=0
PreviewUserPw=1
PreviewDomain=1
PreviewPhoneNumber=0
ShowDialingProgress=1
ShowMonitorIconInTaskBar=0
CustomAuthKey=0
AuthRestrictions=544
IpPrioritizeRemote=1
IpInterfaceMetric=0
IpHeaderCompression=0
IpAddress=0.0.0.0
IpDnsAddress=0.0.0.0
IpDns2Address=0.0.0.0
IpWinsAddress=0.0.0.0
IpWins2Address=0.0.0.0
IpAssign=1
IpNameAssign=1
IpDnsFlags=0
IpNBTFlags=1
TcpWindowSize=0
UseFlags=2
IpSecFlags=0
IpDnsSuffix=
Ipv6Assign=1
Ipv6Address=::
Ipv6PrefixLength=0
Ipv6PrioritizeRemote=1
Ipv6InterfaceMetric=0
Ipv6NameAssign=1
Ipv6DnsAddress=::
Ipv6Dns2Address=::
Ipv6Prefix=0000000000000000
Ipv6InterfaceId=0000000000000000
DisableClassBasedDefaultRoute=0
DisableMobility=0
NetworkOutageTime=0
ProvisionType=0
PreSharedKey=
CacheCredentials=1
NumCustomPolicy=0
NumEku=0
UseMachineRootCert=0
NumServers=0
RouteVersion=1
NumRoutes=0
NumNrptRules=0
AutoTiggerCapable=0
NumAppIds=0
NumClassicAppIds=0
SecurityDescriptor=
ApnInfoProviderId=
ApnInfoUsername=
ApnInfoPassword=
ApnInfoAccessPoint=
ApnInfoAuthentication=1
ApnInfoCompression=0
DeviceComplianceEnabled=0
DeviceComplianceSsoEnabled=0
DeviceComplianceSsoEku=
DeviceComplianceSsoIssuer=
FlagsSet=0
Options=0
DisableDefaultDnsSuffixes=0
NumTrustedNetworks=0
NumDnsSearchSuffixes=0
PowershellCreatedProfile=0
ProxyFlags=0
ProxySettingsModified=0
ProvisioningAuthority=
AuthTypeOTP=0
GREKeyDefined=0
NumPerAppTrafficFilters=0
AlwaysOnCapable=0
DeviceTunnel=0
PrivateNetwork=0

NETCOMPONENTS=
ms_msclient=1
ms_server=1

MEDIA=rastapi
Port=VPN4-0
Device=WAN Miniport (PPTP)

DEVICE=vpn
PhoneNumber=us1.vpnbook.com
AreaCode=
CountryCode=0
CountryID=0
UseDialingRules=0
Comment=
FriendlyName=
LastSelectedPhone=0
PromoteAlternates=0
TryNextAlternateOnFail=1


Sonra bunu RESOURCE olarak projenize gömün.

Size şu kalacak...

strBaglanti ( string bir değişkendir ) içeriği aşağıdaki şekilde kurun.

strLogin  : Login adı
strPass : Parola
strPBK : resource içinden export ettiğiniz PBK dosyasının yolu.

    strBaglanti := 'rasdial.exe'
     + ' '
     + '"VPN_Book"'
     + ' '
     + '"' + strLogin + '"'
     + ' '
     + '"' + strPass + '"'
     + ' '
     + '/phonebook:' + '"' + strPBK + '"'
     ;

- Ben bunu DOS Output takibi ile MEMO içine alarak durumu logluyorum böylece erişim oldu mu olmadı mı basit bir TEXT parse işlemi ile takip edebiliyorum. Size de tavsiyem basitçe budur. 

Unutmadan çıkmadan önce de aşağıdaki şekilde DISCONNECT ediyoruz.

  strBaglanti := 'rasdial.exe "VPN_Book" /DISCONNECT';


Burada "VPN_Book" bağlantı profil adınız oluyor.


EK : Bilgisayar karşısına geçtim projeyi açtım içinden sizi ilgilendiren kısmı alıp paylaşıyorum.

lewatwndrv7xuaalvttl.gif


Kurulu PBK profili USRER klasörümüz içersinden kontrol etmek için de kullandığım fonksiyon şu şekilde.

function VPNBook_Kontrol: String;
Const
 VPN = 'VPN_Book.pbk';
Var
 strUser : String;
 strPBK  : String;
begin
 Result  := '';
 strUser := GetEnvironmentVariable('USERPROFILE'); // C:\Users\arman
 strPBK  := strUser + PathDelim + 'AppData\Roaming\Microsoft\Network\Connections\Pbk\' + VPN;
 if NOT FileExists(strPBK) then begin
   With TResourceStream.Create(HInstance, 'VPNBOOK', RT_RCDATA) do
   begin
     SaveToFile( strPBK );
     Free;
   end;
 end;
 if FileExists(strPBK) then Result := strPBK;
end;

Hepsi bir arada çözüm olsun istedim.

Elinize sağlık. Çok güzel bir çözüm olmuş.
Cevapla
#13
Merhaba.

* Proje çok eskiden yazdığımdan forumda paylaşmak vs. adına kodların terbiyesi bugünkü yazdıklarım gibi değil. Karışık görüntü için üzgünüm.


Kaynak kodlarıyla birlikte aşağıdaki linkten indirebilirsiniz.

image_VPNBoook_GUI.php


indirmeden incelemek isteyenler için kodlar aşağıdaki şekilde.

Kullanım hali.
Uses VPNBook_Helper;

var
  aVPNBook : tVPNBookHelper;

procedure TForm1.FormCreate(Sender: TObject);
begin
  ReportMemoryLeaksOnShutdown := True;

  Edit1.Text := '';
  Edit2.Text := '';
  Memo1.Lines.Text := '';
  aVPNBook      := tVPNBookHelper.Create;
  aVPNBook.Log  := Memo1.Lines;
  aVPNBook.CaptchaBitmap := Image1.Picture.Bitmap;
  aVPNBook.OnConnectionChange := OnConnectionChange;
end;

procedure TForm1.BitBtn2Click(Sender: TObject);
begin
  aVPNBook.Disconnect;
end;

procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  BitBtn2Click(BitBtn2);
  FreeAndNil( aVPNBook );
end;

procedure TForm1.OnConnectionChange( aLoginName, aPassword, aOCRText: String );
begin
  Edit1.Text := aLoginName;
  Edit2.Text := aPassword;
end;

procedure TForm1.BitBtn1Click(Sender: TObject);
begin
  aVPNBook.Connect;
end;

end.

// Sorun olursa...
//
//  01.Open Device Manager
//  02.Find Network Adapters
//  03.Uninstall WAN Miniport (IP), WAN Miniport(IPv6) and WAN Miniport (PPTP).
//  04.Click Action > Scan for hardware changes
//  05.The adapters you just uninstalled should come back
//  06.Try connecting again

// https://www.vpnbook.com/password.php


lghxxylpi0navmcwb5p2.gif

HelperClass
unit VPNBook_Helper;

interface

Uses  Windows, Forms, StdCtrls, Graphics, Classes, Sysutils,
     WinInet, PNGImage, Delphi_VPNBook_OCR;

type
 tConnectionEvent = procedure( aLoginName, aPassword, aOCRText: String ) of object;

type
 tVPNBookHelper = class(TObject)
 private
   FConnectionEvent: tConnectionEvent;
   FLogMemo        : TStrings;
   FCaptchaBitmap  : TBitmap;
   FLogin, FPass,
   FOCRText        : String;
   procedure   GetDosOutput( strCmd, strDizin: string );
   function    OCRImage(aBitmap: TBitmap): String;
   function    VPNBook_GetPassword(aGelenResim: TBitmap = nil ): String;
   function    CheckPBKFile: String;
 public
   constructor Create;
   destructor  Destroy; override;
   procedure   Connect;
   procedure   Disconnect;
   property    Log : TStrings read FLogMemo write FLogMemo;
   property    CaptchaBitmap : TBitmap read FCaptchaBitmap write FCaptchaBitmap;
   property    LoginName : string read FLogin;
   property    LoginPass : string read FPass;
   property    OnConnectionChange : tConnectionEvent read FConnectionEvent write FConnectionEvent;
 end;

implementation

constructor tVPNBookHelper.Create;
begin
 inherited;
end;

destructor  tVPNBookHelper.Destroy;
begin

 inherited;
end;

procedure   tVPNBookHelper.Connect;
Var
 strPBK,
 strBaglanti : String;
begin
 strPBK  := CheckPBKFile;
 FLogin  := 'vpnbook';
 if strPBK <> '' then
 begin
   FPass := VPNBook_GetPassword( FCaptchaBitmap );

   if FPass = '' then
   begin
     //ShowMessage('Parola Gelmedi .... ');
     Exit;
   end;
   if Assigned( FConnectionEvent )then FConnectionEvent( FLogin, FPass, FOcrText );
   strBaglanti := 'rasdial.exe'
     + ' '
     + '"VPN_Book"'
     + ' '
     + '"' + FLogin + '"'
     + ' '
     + '"' + FPass + '"'
     + ' '
     + '/phonebook:' + '"' + strPBK + '"'
     ;

   if Assigned( FLogMemo ) then FLogMemo.Add('Bağlantı Kuruluyor');
   GetDosOutput( strBaglanti, ExtractFilePath(ParamStr(0)) );
 end;
end;

procedure   tVPNBookHelper.Disconnect;
Var
 strBaglanti : String;
begin
 strBaglanti := 'rasdial.exe "VPN_Book" /DISCONNECT';
 if Assigned(FLogMemo) then  FLogMemo.Add('Bağlantı kesiliyor...');
 GetDosOutput( strBaglanti, ExtractFilePath(ParamStr(0)) );
end;

function    tVPNBookHelper.OCRImage( aBitmap: TBitmap ): String;
 function GetTempDir: string;
 var // GetTempDir - User Temp Dizini
   TempDir:     DWORD;
 begin
   SetLength(Result, MAX_PATH);
   TempDir := GetTempPath(MAX_PATH, PChar(Result));
   SetLength(Result, TempDir);
 end;
type
 TOCR_GiB = function ( aBitmapHandle: HBitmap; aResult: PChar; var aBuflen: Word ): boolean; StdCall;
Var
 OCR_Image     : TOCR_GiB;
 dllHand       : THandle;
 strDLL        : String;
 OcrStr        : string;
 OcrStrLen     : Word;
begin
 Result := '';
 if aBitmap = nil then Exit;
 strDLL := GetTempDir + strOrjDosya;

 With TFileStream.Create( strDLL, fmCreate ) do try
   Write( Dizi_Delphi_VPNBook_OCR, High( Dizi_Delphi_VPNBook_OCR )+1 );
 finally
   free;
 end;

 dllHand := LoadLibrary( PChar( strDLL ) ) ;
 if dllHand <> 0 then
 begin
   @OCR_Image := GetProcAddress(dllHand, 'OCR_Image') ;
   if Assigned (OCR_Image) then
   begin
     OcrStrLen := 255;
     SetLength(OcrStr, OcrStrLen);
       OCR_Image( aBitmap.Handle, PChar(OcrStr), OcrStrLen );
     SetLength(OcrStr, OcrStrLen);
     Result := OcrStr;
   end
   else;// ShowMessage('DLL içerisinde istenen fonksiyonu Export edilmemiş...');
   @OCR_Image := nil;
   FreeLibrary(dllHand) ;
 end
 else;// ShowMessage('DLL dosyası bulunamadı veya yüklenemedi...');

 if FileExists( strDLL ) then DeleteFile( strDLL );
end;

function    tVPNBookHelper.VPNBook_GetPassword( aGelenResim: TBitmap = nil ): String;
 function DownloadURL_NOCache( const aUrl: string; var aStream: TMemoryStream ): Boolean;
 var
   hSession: HINTERNET;
   hService: HINTERNET;
   lpBuffer: array[0..1024 + 1] of Byte;
   dwBytesRead: DWORD;
 begin
   Result := False;
   aStream.Position := 0;

   hSession := InternetOpen( 'VPNBookPassword', INTERNET_OPEN_TYPE_PRECONFIG, nil, nil, 0);
   try
     if Assigned(hSession) then
     begin
       hService := InternetOpenUrl(hSession, PChar(aUrl), nil, 0, INTERNET_FLAG_RELOAD, 0);
       if Assigned(hService) then
         try
           while True do
           begin
             dwBytesRead := 1024;
             InternetReadFile(hService, @lpBuffer, 1024, dwBytesRead);
             if dwBytesRead = 0 then break;
             lpBuffer[dwBytesRead] := $0;
             aStream.Write( lpBuffer, sizeOf(lpBuffer) );
           end;
           Result := True;
         finally
           InternetCloseHandle(hService);
         end;
     end;
   finally
     InternetCloseHandle(hSession);
   end;
 end;
var
 aStream    : TMemoryStream;
 aPNGImage  : TPngImage;
 aPassword  : TBitmap;
 boolParolaImgGeldi : Boolean;
begin
 aStream   := TMemoryStream.Create;
 aPassword := TBitmap.Create;
 aPNGImage := TPngImage.Create;

 // Password image download
 // ------------------------------------------------------------------------ //
 // ( URL https olduğundan InternetReadFile kullandım )
 // ( Indy SSL lib ihtiyacı olmasın istedim !!!       )
 try
   boolParolaImgGeldi := DownloadURL_NOCache( 'https://www.vpnbook.com/password.php', aStream );

   if boolParolaImgGeldi then
   begin
     aStream.Position := 0;
     aPNGImage.LoadFromStream( aStream );
     aPassword.Assign(aPNGImage);
   end;
 finally
   aStream.Free;
   aPNGImage.Free;
 end;

 if NOT boolParolaImgGeldi then exit;

 try
   // Gelen Resmi Görelim...
   // ---------------------------------------------------------------------- //
   if aGelenResim <> nil then begin
     aGelenResim.Assign(aPassword);
   end;

   // OCR
   // ---------------------------------------------------------------------- //
   Result := OCRImage( aPassword );
 finally
   aPassword.Free;
 end;
end;

procedure   tVPNBookHelper.GetDosOutput(strCmd, strDizin: string );
var
 SA               : TSecurityAttributes;
 SI               : TStartupInfo;
 PI               : TProcessInformation;
 hRead,
 hWrite           : THandle;
 boolOK           : Boolean;
 Buffer           : array[0..255] of AnsiChar;
 cBytesRead       : Cardinal;
 boolH            : Boolean;
begin
 with SA do begin
   nLength              := SizeOf(SA);
   bInheritHandle       := True;
   lpSecurityDescriptor := nil;
 end;
 CreatePipe(hRead, hWrite, @SA, 0);

 try
   with SI do
   begin
     FillChar(SI, SizeOf(SI), 0);
     cb          := SizeOf(SI);
     dwFlags     := STARTF_USESHOWWINDOW or STARTF_USESTDHANDLES;
     wShowWindow := SW_HIDE;
     hStdInput   := GetStdHandle(STD_INPUT_HANDLE);
     hStdOutput  := hWrite;
     hStdError   := hWrite;
   end;
   boolH := CreateProcess( nil
                         , PChar('cmd.exe /C ' + strCmd)
                         , nil
                         , nil
                         , True
                         , CREATE_NO_WINDOW
                         , nil
                         , PChar(strDizin)
                         , SI
                         , PI
                         );
   CloseHandle(hWrite);
   if boolH then
     try
       if FLogMemo <> nil then // Memo'ya çıktı istemezseniz paramtereyi nil bırakın yeter...
       repeat
         boolOK := ReadFile(hRead, Buffer, 255, cBytesRead, nil);
         if cBytesRead > 0 then
         begin
           Buffer[cBytesRead] := #0;
           FLogMemo.Text := FLogMemo.Text + String(Buffer);
           Application.ProcessMessages;
         end;
       until not boolOK or (cBytesRead = 0);

    // WaitForSingleObject(PI.hProcess, INFINITE);// veya
       while WaitForSingleObject(PI.hProcess, 10) <> WAIT_OBJECT_0 do
       begin
         Application.ProcessMessages;
       end;
     finally
       CloseHandle(PI.hThread);
       CloseHandle(PI.hProcess);
     end;
 finally
   CloseHandle(hRead);
 end;
end;

function    tVPNBookHelper.CheckPBKFile: String;
Const
 VPN = 'VPN_Book.pbk';
Var
 strUser : String;
 strPBK  : String;
begin
 Result  := '';
 strUser := GetEnvironmentVariable('USERPROFILE'); // C:\Users\arman
 strPBK  := strUser + PathDelim + 'AppData\Roaming\Microsoft\Network\Connections\Pbk\' + VPN;
 if NOT FileExists(strPBK) then begin
   With TResourceStream.Create(HInstance, 'VPNBOOK', RT_RCDATA) do
   begin
     SaveToFile( strPBK );
     Free;
   end;
 end;
 if FileExists(strPBK) then Result := strPBK;
end;

end.
Saygılarımla
Muharrem ARMAN

guplouajuixjzfm15eqb.gif
Cevapla
#14
Teşekkür ederim @mrmarman hocam
Cevapla
#15
Tesekkür elinize kolunuza saglik.
Cevapla
#16
Yazmayı unutmuşum, başlığı okuyanlar nedenini anlamamış olabilirler; 

* VPNBook günlük olarak erişim parolasını yenisiyle değiştiriyor. Güncel parolayı da ilk zamanlarda metin olarak verirdi parse ederek bulurduk. Sonradan PNG Image olarak vermeye başladı. OCR işlemi bu nedenle konuya dahil olmuştur. 

* Bunun kadar efektif bir VPN gören duyan varsa buraya yazarsa da sevinirim. Bulduklarımdan sadece bu sadık kaldı, diğerleri ya paralı ve windows erişimli oldu ya da yine paralı olarak üçüncü parti yazılım ile erişim mantığı ile çalışmaya başladı.
Saygılarımla
Muharrem ARMAN

guplouajuixjzfm15eqb.gif
Cevapla




Konuyu Okuyanlar: 1 Ziyaretçi