Elimde Word dosyasi var, bir nevi Template gibi düsünebilirsiniz. Burada belirli alanlari doldurmam gerekiyor. Excel den olsa birkac kez yaptigimdan problem olmuyor da, Word ile hic calismadim ve hicbir fikrim yok. Bana yardimci olabilirmisiniz ?
Merhaba arkadaslar,
herkese hayirli Ramazanlar diliyorum.
Word dosyasina yazdirmayi malesef beceremedim. Gri olarak belirlenmis yerlere birde siz yazdirmaya deniyebilirmisiniz ?
08-05-2019, Saat: 18:40 (Son Düzenleme: 09-05-2019, Saat: 09:56, Düzenleyen: mrmarman.
Sebep: Kod disiplininde Word değişken adını ihmal etmişim. Forum Code Tag renklendirmesiyle fark ettim.
)
Buyrun.
Uses ComObj;
procedure TForm1.BitBtn1Click(Sender: TObject);
Const
wdFieldFormTextInput = $00000046;
wdFieldFormCheckBox = $00000047;
var
aWord, aDoc : OleVariant;
aIdx : Integer;
begin
with TOpenDialog.Create(nil)
do
try
Options := [];
Filter := 'Word Dosyaları *.doc, *.docx|*.doc;*.docx|Tüm Dosyalar *.*|*.*';
FilterIndex := 1;
if Execute then
begin
aWord := CreateOleObject('Word.Application');
try
aWord.Documents.Open( FileName );
aDoc := aWord.ActiveDocument;
For aIdx := 1 to aDoc.FormFields.Count do
begin
case aDoc.FormFields.Item(aIdx).Type of
wdFieldFormCheckBox :
begin
if aDoc.FormFields.Item(aIdx).CheckBox.Value
then Memo1.Lines.Add( Format( 'Idx: %.3d EskiValue: "Checked"', [ aIdx ] ) )
else Memo1.Lines.Add( Format( 'Idx: %.3d EskiValue: "UnChecked"', [ aIdx ] ) );
// Checked işaret Koyalım...
aDoc.FormFields.Item(aIdx).CheckBox.Value := True;
// Yeni Değeri yerinden okuyarak Yazalım...
if aDoc.FormFields.Item(aIdx).CheckBox.Value
then Memo1.Lines.Add( Format( ' Idx: %.3d YeniValue: "Checked"', [ aIdx ] ) )
else Memo1.Lines.Add( Format( ' Idx: %.3d YeniValue: "UnChecked"', [ aIdx ] ) );
end;
wdFieldFormTextInput :
begin
Memo1.Lines.Add( Format( 'Idx: %.3d Value: "%s"', [ aIdx, aDoc.FormFields.Item(aIdx).Result ] ) );
// Yeni Değer Yazalım...
aDoc.FormFields.Item(aIdx).Result := Format('Index: %.3d', [ aIdx ]);
// Yeni Değeri yerinden okuyarak Yazalım...
Memo1.Lines.Add( Format( ' Idx: %.3d YeniValue: "%s"', [ aIdx, aDoc.FormFields.Item(aIdx).Result ] ) );
end;
end;
end;
finally
aWord.Visible := True;
aWord := Unassigned;
aDoc := Unassigned;
end;
end;
finally
Free;
end;
end;
Word yerine RTF formatında rapor tasarlayarak ilgili alanları doldurabilirsiniz. EkRTF componentini incelemenizi öneririm. Geçmişte çok işime yaramıştı.